pkgs/by-name/tu/turbo-unwrapped/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   apple-sdk_11,
   5   capnproto,
   6   extra-cmake-modules,
   7   fetchFromGitHub,
   8   fontconfig,
   9   llvmPackages,
  10   nix-update-script,
  11   openssl,
  12   pkg-config,
  13   protobuf,
  14   rust-jemalloc-sys,
  15   rustPlatform,
  16   zlib,
  17 }:
  18
  19 rustPlatform.buildRustPackage rec {
  20   pname = "turbo-unwrapped";
  21   version = "2.2.3";
  22
  23   src = fetchFromGitHub {
  24     owner = "vercel";
  25     repo = "turbo";
  26     rev = "refs/tags/v${version}";
  27     hash = "sha256-MDvwitzZVPVjdIVEAV1aKMAVeLSTMM2owH5RSfVg+rU=";
  28   };
  29
  30   cargoHash = "sha256-XBI/eiOyKk80ZDFLD2HCTFYRWvC7qtzQY/zFCmKdKSM=";
  31
  32   nativeBuildInputs =
  33     [
  34       capnproto
  35       extra-cmake-modules
  36       pkg-config
  37       protobuf
  38     ]
  39     # https://github.com/vercel/turbo/blob/ea740706e0592b3906ab34c7cfa1768daafc2a84/CONTRIBUTING.md#linux-dependencies
  40     ++ lib.optional stdenv.hostPlatform.isLinux llvmPackages.bintools;
  41
  42   buildInputs = [
  43     fontconfig
  44     openssl
  45     rust-jemalloc-sys
  46     zlib
  47   ] ++ lib.optional stdenv.hostPlatform.isDarwin apple-sdk_11;
  48
  49   cargoBuildFlags = [
  50     "--package"
  51     "turbo"
  52   ];
  53
  54   # Browser tests time out with chromium and google-chrome
  55   doCheck = false;
  56
  57   env = {
  58     # nightly features are used
  59     RUSTC_BOOTSTRAP = 1;
  60   };
  61
  62   passthru = {
  63     updateScript = nix-update-script {
  64       extraArgs = [
  65         "--version-regex"
  66         "'v(\d+\.\d+\.\d+)'"
  67       ];
  68     };
  69   };
  70
  71   meta = {
  72     description = "High-performance build system for JavaScript and TypeScript codebases";
  73     homepage = "https://turbo.build/";
  74     changelog = "https://github.com/vercel/turbo/releases/tag/v${version}";
  75     license = lib.licenses.mit;
  76     maintainers = with lib.maintainers; [
  77       dlip
  78       getchoo
  79     ];
  80     mainProgram = "turbo";
  81   };
  82 }