nixos/modules/programs/turbovnc.nix

   1 # Global configuration for the SSH client.
   2
   3 { config, lib, pkgs, ... }:
   4
   5 with lib;
   6
   7 let
   8   cfg = config.programs.turbovnc;
   9 in
  10 {
  11   options = {
  12
  13     programs.turbovnc = {
  14
  15       ensureHeadlessSoftwareOpenGL = mkOption {
  16         type = types.bool;
  17         default = false;
  18         description = lib.mdDoc ''
  19           Whether to set up NixOS such that TurboVNC's built-in software OpenGL
  20           implementation works.
  21
  22           This will enable {option}`hardware.opengl.enable` so that OpenGL
  23           programs can find Mesa's llvmpipe drivers.
  24
  25           Setting this option to `false` does not mean that software
  26           OpenGL won't work; it may still work depending on your system
  27           configuration.
  28
  29           This option is also intended to generate warnings if you are using some
  30           configuration that's incompatible with using headless software OpenGL
  31           in TurboVNC.
  32         '';
  33       };
  34
  35     };
  36
  37   };
  38
  39   config = mkIf cfg.ensureHeadlessSoftwareOpenGL {
  40
  41     # TurboVNC has builtin support for Mesa llvmpipe's `swrast`
  42     # software rendering to implement GLX (OpenGL on Xorg).
  43     # However, just building TurboVNC with support for that is not enough
  44     # (it only takes care of the X server side part of OpenGL);
  45     # the indiviudual applications (e.g. `glxgears`) also need to directly load
  46     # the OpenGL libs.
  47     # Thus, this creates `/run/opengl-driver` populated by Mesa so that the applications
  48     # can find the llvmpipe `swrast.so` software rendering DRI lib via `libglvnd`.
  49     # This comment exists to explain why `hardware.` is involved,
  50     # even though 100% software rendering is used.
  51     hardware.opengl.enable = true;
  52
  53   };
  54 }