pkgs/os-specific/darwin/aldente/default.nix

   1 { lib
   2 , stdenvNoCC
   3 , fetchurl
   4 , undmg
   5 }:
   6
   7 stdenvNoCC.mkDerivation (finalAttrs: {
   8   pname = "aldente";
   9   version = "1.22.3";
  10
  11   src = fetchurl {
  12     url = "https://github.com/davidwernhart/aldente-charge-limiter/releases/download/${finalAttrs.version}/AlDente.dmg";
  13     hash = "sha256-pSqBDDumCbORLQ+B3skSqKmgG2KybR5Zb4ojiNQcAaM=";
  14   };
  15
  16   dontBuild = true;
  17   dontFixup = true;
  18
  19   nativeBuildInputs = [ undmg ];
  20
  21   # AlDente.dmg is not HFS formatted, default unpackPhase fails
  22   # https://discourse.nixos.org/t/help-with-error-only-hfs-file-systems-are-supported-on-ventura
  23   unpackCmd = ''
  24     if ! [[ "$curSrc" =~ \.dmg$ ]]; then return 1; fi
  25     mnt=$(mktemp -d -t ci-XXXXXXXXXX)
  26
  27     function finish {
  28       /usr/bin/hdiutil detach $mnt -force
  29     }
  30     trap finish EXIT
  31
  32     /usr/bin/hdiutil attach -nobrowse -readonly $src -mountpoint $mnt
  33
  34     shopt -s extglob
  35     DEST="$PWD"
  36     (cd "$mnt"; cp -a !(Applications) "$DEST/")
  37   '';
  38
  39   sourceRoot = "AlDente.app";
  40
  41   installPhase = ''
  42     runHook preInstall
  43
  44     mkdir -p $out/Applications/AlDente.app
  45     cp -R . $out/Applications/AlDente.app
  46
  47     runHook postInstall
  48   '';
  49
  50   meta = with lib; {
  51     description = "macOS tool to limit maximum charging percentage";
  52     homepage = "https://apphousekitchen.com";
  53     changelog = "https://github.com/davidwernhart/aldente-charge-limiter/releases/tag/${finalAttrs.version}";
  54     license = with licenses; [ unfree ];
  55     sourceProvenance = with sourceTypes; [ binaryNativeCode ];
  56     maintainers = with maintainers; [ stepbrobd ];
  57     platforms = [ "aarch64-darwin" "x86_64-darwin" ];
  58   };
  59 })