pkgs/os-specific/linux/isgx/default.nix

   1 { stdenv, lib, fetchFromGitHub, kernel }:
   2
   3 stdenv.mkDerivation rec {
   4   name = "isgx-${version}-${kernel.version}";
   5   version = "2.14";
   6
   7   src = fetchFromGitHub {
   8     owner = "intel";
   9     repo = "linux-sgx-driver";
  10     rev = "sgx_diver_${version}"; # Typo is upstream's.
  11     sha256 = "0kbbf2inaywp44lm8ig26mkb36jq3smsln0yp6kmrirdwc3c53mi";
  12   };
  13
  14   hardeningDisable = [ "pic" ];
  15
  16   nativeBuildInputs = kernel.moduleBuildDependencies;
  17
  18   makeFlags = [
  19     "KDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
  20   ];
  21
  22   installPhase = ''
  23     runHook preInstall
  24     install -D isgx.ko -t $out/lib/modules/${kernel.modDirVersion}/kernel/drivers/intel/sgx
  25     runHook postInstall
  26   '';
  27
  28   enableParallelBuilding = true;
  29
  30   meta = with lib; {
  31     description = "Intel SGX Linux Driver";
  32     longDescription = ''
  33       The linux-sgx-driver project (isgx) hosts an out-of-tree driver
  34       for the Linux* Intel(R) SGX software stack, which would be used
  35       until the driver upstreaming process is complete (before 5.11.0).
  36
  37       It is used to support Enhanced Privacy Identification (EPID)
  38       based attestation on the platforms without Flexible Launch Control.
  39     '';
  40     homepage = "https://github.com/intel/linux-sgx-driver";
  41     license = with licenses; [ bsd3 /* OR */ gpl2Only ];
  42     maintainers = [ ];
  43     platforms = [ "x86_64-linux" ];
  44   };
  45 }