pkgs/development/interpreters/jimtcl/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4
   5 , asciidoc
   6 , pkg-config
   7 , inetutils
   8 , tcl
   9
  10 , sqlite
  11 , readline
  12 , SDL
  13 , SDL_gfx
  14 , openssl
  15
  16 , SDLSupport ? true
  17 }:
  18
  19 stdenv.mkDerivation (finalAttrs: {
  20   pname = "jimtcl";
  21   version = "0.82";
  22
  23   src = fetchFromGitHub {
  24     owner = "msteveb";
  25     repo = "jimtcl";
  26     rev = finalAttrs.version;
  27     sha256 = "sha256-CDjjrxpoTbLESAbCiCjQ8+E/oJP87gDv9SedQOzH3QY=";
  28   };
  29
  30   nativeBuildInputs = [
  31     pkg-config
  32     asciidoc
  33     tcl
  34   ];
  35
  36   buildInputs = [
  37     sqlite
  38     readline
  39     openssl
  40   ] ++ (lib.optionals SDLSupport [
  41     SDL
  42     SDL_gfx
  43   ]);
  44
  45   configureFlags = [
  46     "--shared"
  47     "--with-ext=oo"
  48     "--with-ext=tree"
  49     "--with-ext=binary"
  50     "--with-ext=sqlite3"
  51     "--with-ext=readline"
  52     "--with-ext=json"
  53     "--enable-utf8"
  54     "--ipv6"
  55   ] ++ (lib.optional SDLSupport "--with-ext=sdl");
  56
  57   enableParallelBuilding = true;
  58
  59   doCheck = true;
  60   preCheck = ''
  61     # test exec2-3.2 fails depending on platform or sandboxing (?)
  62     rm tests/exec2.test
  63     # requires internet access
  64     rm tests/ssl.test
  65     # test fails due to timing in some environments
  66     # https://github.com/msteveb/jimtcl/issues/282
  67     rm tests/timer.test
  68   '';
  69
  70   # test posix-1.6 needs the "hostname" command
  71   nativeCheckInputs = [ inetutils ];
  72
  73   meta = {
  74     description = "Open source small-footprint implementation of the Tcl programming language";
  75     homepage = "http://jim.tcl.tk/";
  76     license = lib.licenses.bsd2;
  77     platforms = lib.platforms.all;
  78     maintainers = with lib.maintainers; [ dbohdan fgaz ];
  79   };
  80 })