nixos/modules/programs/obs-studio.nix

   1 {
   2   pkgs,
   3   lib,
   4   config,
   5   ...
   6 }:
   7
   8 let
   9   cfg = config.programs.obs-studio;
  10 in
  11 {
  12   options.programs.obs-studio = {
  13     enable = lib.mkEnableOption "Free and open source software for video recording and live streaming";
  14
  15     package = lib.mkPackageOption pkgs "obs-studio" { example = "obs-studio"; };
  16
  17     finalPackage = lib.mkOption {
  18       type = lib.types.package;
  19       visible = false;
  20       readOnly = true;
  21       description = "Resulting customized OBS Studio package.";
  22     };
  23
  24     plugins = lib.mkOption {
  25       default = [ ];
  26       example = lib.literalExpression "[ pkgs.obs-studio-plugins.wlrobs ]";
  27       description = "Optional OBS plugins.";
  28       type = lib.types.listOf lib.types.package;
  29     };
  30
  31     enableVirtualCamera = lib.mkOption {
  32       type = lib.types.bool;
  33       default = false;
  34       description = ''
  35         Installs and sets up the v4l2loopback kernel module, necessary for OBS
  36         to start a virtual camera.
  37       '';
  38     };
  39   };
  40
  41   config = lib.mkIf cfg.enable {
  42     programs.obs-studio.finalPackage = pkgs.wrapOBS.override { obs-studio = cfg.package; } {
  43       plugins = cfg.plugins;
  44     };
  45
  46     environment.systemPackages = [ cfg.finalPackage ];
  47
  48     boot = lib.mkIf cfg.enableVirtualCamera {
  49       kernelModules = [ "v4l2loopback" ];
  50       extraModulePackages = [ config.boot.kernelPackages.v4l2loopback ];
  51
  52       extraModprobeConfig = ''
  53         options v4l2loopback devices=1 video_nr=1 card_label="OBS Cam" exclusive_caps=1
  54       '';
  55     };
  56
  57     security.polkit.enable = lib.mkIf cfg.enableVirtualCamera true;
  58   };
  59
  60   meta.maintainers = with lib.maintainers; [
  61     CaptainJawZ
  62     GaetanLepage
  63   ];
  64 }