pkgs/by-name/ay/ayatana-indicator-messages/package.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchFromGitHub,
   5   gitUpdater,
   6   nixosTests,
   7   testers,
   8   accountsservice,
   9   cmake,
  10   dbus-test-runner,
  11   withDocumentation ? true,
  12   docbook_xsl,
  13   docbook_xml_dtd_45,
  14   glib,
  15   gobject-introspection,
  16   gtest,
  17   gtk-doc,
  18   intltool,
  19   lomiri,
  20   pkg-config,
  21   python3,
  22   systemd,
  23   vala,
  24   wrapGAppsHook3,
  25 }:
  26
  27 stdenv.mkDerivation (finalAttrs: {
  28   pname = "ayatana-indicator-messages";
  29   version = "24.5.0";
  30
  31   src = fetchFromGitHub {
  32     owner = "AyatanaIndicators";
  33     repo = "ayatana-indicator-messages";
  34     rev = "refs/tags/${finalAttrs.version}";
  35     hash = "sha256-D1181eD2mAVXEa7RLXXC4b2tVGrxbh0WWgtbC1anHH0=";
  36   };
  37
  38   outputs = [
  39     "out"
  40     "dev"
  41   ] ++ lib.optionals withDocumentation [ "devdoc" ];
  42
  43   postPatch =
  44     ''
  45       # Uses pkg_get_variable, cannot substitute prefix with that
  46       substituteInPlace data/CMakeLists.txt \
  47         --replace-fail "\''${SYSTEMD_USER_DIR}" "$out/lib/systemd/user"
  48
  49       # Bad concatenation
  50       substituteInPlace libmessaging-menu/messaging-menu.pc.in \
  51         --replace-fail "\''${exec_prefix}/@CMAKE_INSTALL_LIBDIR@" '@CMAKE_INSTALL_FULL_LIBDIR@' \
  52         --replace-fail "\''${prefix}/@CMAKE_INSTALL_INCLUDEDIR@" '@CMAKE_INSTALL_FULL_INCLUDEDIR@'
  53
  54       # Fix tests with gobject-introspection 1.80 not installing GLib introspection data
  55       substituteInPlace tests/CMakeLists.txt \
  56         --replace-fail 'GI_TYPELIB_PATH=\"' 'GI_TYPELIB_PATH=\"$GI_TYPELIB_PATH$\{GI_TYPELIB_PATH\:+\:\}'
  57     ''
  58     + lib.optionalString (!withDocumentation) ''
  59       sed -i CMakeLists.txt \
  60         '/add_subdirectory(doc)/d'
  61     '';
  62
  63   strictDeps = true;
  64
  65   nativeBuildInputs =
  66     [
  67       cmake
  68       glib # For glib-compile-schemas
  69       intltool
  70       pkg-config
  71       vala
  72       wrapGAppsHook3
  73     ]
  74     ++ lib.optionals withDocumentation [
  75       docbook_xsl
  76       docbook_xml_dtd_45
  77       gtk-doc
  78     ];
  79
  80   buildInputs = [
  81     accountsservice
  82     lomiri.cmake-extras
  83     glib
  84     gobject-introspection
  85     systemd
  86   ];
  87
  88   nativeCheckInputs = [
  89     (python3.withPackages (
  90       ps: with ps; [
  91         pygobject3
  92         python-dbusmock
  93       ]
  94     ))
  95   ];
  96
  97   checkInputs = [
  98     dbus-test-runner
  99     gtest
 100   ];
 101
 102   cmakeFlags = [
 103     "-DENABLE_TESTS=${lib.boolToString finalAttrs.finalPackage.doCheck}"
 104     "-DGSETTINGS_LOCALINSTALL=ON"
 105     "-DGSETTINGS_COMPILE=ON"
 106   ];
 107
 108   makeFlags = lib.optionals withDocumentation [
 109     # gtk-doc doesn't call ld with the correct arguments
 110     # ld: ...: undefined reference to symbol 'strncpy@@GLIBC_2.2.5', 'qsort@@GLIBC_2.2.5'
 111     "LD=${stdenv.cc.targetPrefix}cc"
 112   ];
 113
 114   doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
 115
 116   preCheck = ''
 117     # test-client imports gir, whose solib entry points to final store location
 118     install -Dm644 libmessaging-menu/libmessaging-menu.so.0.0.0 $out/lib/libmessaging-menu.so.0
 119   '';
 120
 121   postCheck = ''
 122     # remove the above solib-installation, let it be done properly
 123     rm -r $out
 124   '';
 125
 126   preInstall = lib.optionalString withDocumentation ''
 127     # installing regenerates docs, generated files are created without write permissions, errors out while trying to overwrite them
 128     chmod +w doc/reference/html/*
 129   '';
 130
 131   # Indicators that talk to it may issue requests to parse desktop files, which needs binaries in Exec on PATH
 132   # messaging_menu_app_set_desktop_id -> g_desktop_app_info_new -...-> g_desktop_app_info_load_from_keyfile -> g_find_program_for_path
 133   # When launched via systemd, PATH is very narrow
 134   preFixup = ''
 135     gappsWrapperArgs+=(
 136       --suffix PATH : '/run/current-system/sw/bin'
 137     )
 138   '';
 139
 140   passthru = {
 141     ayatana-indicators = {
 142       ayatana-indicator-messages = [
 143         "ayatana"
 144         "lomiri"
 145       ];
 146     };
 147     tests = {
 148       pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
 149       vm = nixosTests.ayatana-indicators;
 150     };
 151     updateScript = gitUpdater { };
 152   };
 153
 154   meta = {
 155     description = "Ayatana Indicator Messages Applet";
 156     longDescription = ''
 157       The -messages Ayatana System Indicator is the messages menu indicator for Unity7, MATE and Lomiri (optionally for
 158       others, e.g. XFCE, LXDE).
 159     '';
 160     homepage = "https://github.com/AyatanaIndicators/ayatana-indicator-messages";
 161     license = lib.licenses.gpl3Only;
 162     platforms = lib.platforms.linux;
 163     maintainers = with lib.maintainers; [ OPNA2608 ];
 164     pkgConfigModules = [ "messaging-menu" ];
 165   };
 166 })