pkgs/by-name/gl/glfw3/package.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , cmake
   5 , pkg-config
   6 , libGL
   7 , vulkan-loader
   8 , libXrandr
   9 , libXinerama
  10 , libXcursor
  11 , libX11
  12 , libXi
  13 , libXext
  14 , darwin
  15 , fixDarwinDylibNames
  16 , wayland
  17 , wayland-scanner
  18 , wayland-protocols
  19 , libxkbcommon
  20 , libdecor
  21 , withMinecraftPatch ? false
  22 }:
  23 let
  24   version = "3.4";
  25 in
  26 stdenv.mkDerivation {
  27   pname = "glfw${lib.optionalString withMinecraftPatch "-minecraft"}";
  28   inherit version;
  29
  30   src = fetchFromGitHub {
  31     owner = "glfw";
  32     repo = "GLFW";
  33     rev = version;
  34     hash = "sha256-FcnQPDeNHgov1Z07gjFze0VMz2diOrpbKZCsI96ngz0=";
  35   };
  36
  37   # Fix linkage issues on X11 (https://github.com/NixOS/nixpkgs/issues/142583)
  38   patches = [
  39     ./x11.patch
  40   ] ++ lib.optionals withMinecraftPatch [
  41     ./0009-Defer-setting-cursor-position-until-the-cursor-is-lo.patch
  42   ];
  43
  44   propagatedBuildInputs = lib.optionals (!stdenv.hostPlatform.isWindows) [ libGL ];
  45
  46   nativeBuildInputs = [ cmake pkg-config ]
  47     ++ lib.optionals stdenv.hostPlatform.isDarwin [ fixDarwinDylibNames ]
  48     ++ lib.optionals stdenv.hostPlatform.isLinux [ wayland-scanner ];
  49
  50   buildInputs =
  51     lib.optionals stdenv.hostPlatform.isDarwin (with darwin.apple_sdk.frameworks; [ Carbon Cocoa Kernel ])
  52     ++ lib.optionals stdenv.hostPlatform.isLinux [
  53       wayland
  54       wayland-protocols
  55       libxkbcommon
  56       libX11
  57       libXrandr
  58       libXinerama
  59       libXcursor
  60       libXi
  61       libXext
  62     ];
  63
  64   cmakeFlags = [
  65     "-DBUILD_SHARED_LIBS=ON"
  66   ] ++ lib.optionals (!stdenv.hostPlatform.isDarwin && !stdenv.hostPlatform.isWindows) [
  67     "-DCMAKE_C_FLAGS=-D_GLFW_GLX_LIBRARY='\"${lib.getLib libGL}/lib/libGL.so.1\"'"
  68     "-DCMAKE_C_FLAGS=-D_GLFW_EGL_LIBRARY='\"${lib.getLib libGL}/lib/libEGL.so.1\"'"
  69     "-DCMAKE_C_FLAGS=-D_GLFW_VULKAN_LIBRARY='\"${lib.getLib vulkan-loader}/lib/libvulkan.so.1\"'"
  70   ];
  71
  72   postPatch = lib.optionalString stdenv.hostPlatform.isLinux ''
  73     substituteInPlace src/wl_init.c \
  74       --replace-fail "libxkbcommon.so.0" "${lib.getLib libxkbcommon}/lib/libxkbcommon.so.0" \
  75       --replace-fail "libdecor-0.so.0" "${lib.getLib libdecor}/lib/libdecor-0.so.0" \
  76       --replace-fail "libwayland-client.so.0" "${lib.getLib wayland}/lib/libwayland-client.so.0" \
  77       --replace-fail "libwayland-cursor.so.0" "${lib.getLib wayland}/lib/libwayland-cursor.so.0" \
  78       --replace-fail "libwayland-egl.so.1" "${lib.getLib wayland}/lib/libwayland-egl.so.1"
  79   '';
  80
  81   # glfw may dlopen libwayland-client.so:
  82   postFixup = lib.optionalString stdenv.hostPlatform.isLinux ''
  83     patchelf ''${!outputLib}/lib/libglfw.so --add-rpath ${lib.getLib wayland}/lib
  84   '';
  85
  86   meta = with lib; {
  87     description = "Multi-platform library for creating OpenGL contexts and managing input, including keyboard, mouse, joystick and time";
  88     homepage = "https://www.glfw.org/";
  89     license = licenses.zlib;
  90     maintainers = with maintainers; [ marcweber Scrumplex twey ];
  91     platforms = platforms.unix ++ platforms.windows;
  92   };
  93 }