pkgs/by-name/je/jellyfin-ffmpeg/package.nix

   1 { ffmpeg_7-full
   2 , fetchFromGitHub
   3 , fetchpatch
   4 , lib
   5 }:
   6
   7 let
   8   version = "7.0.2-5";
   9 in
  10
  11 (ffmpeg_7-full.override {
  12   inherit version; # Important! This sets the ABI.
  13   source = fetchFromGitHub {
  14     owner = "jellyfin";
  15     repo = "jellyfin-ffmpeg";
  16     rev = "v${version}";
  17     hash = "sha256-cqyXQNx65eLEumOoSCucNpAqShMhiPqzsKc/GjKKQOA=";
  18   };
  19 }).overrideAttrs (old: {
  20   pname = "jellyfin-ffmpeg";
  21
  22   configureFlags = old.configureFlags ++ [
  23     "--extra-version=Jellyfin"
  24     "--disable-ptx-compression" # https://github.com/jellyfin/jellyfin/issues/7944#issuecomment-1156880067
  25   ];
  26
  27   postPatch = ''
  28     for file in $(cat debian/patches/series); do
  29       patch -p1 < debian/patches/$file
  30     done
  31
  32     ${old.postPatch or ""}
  33   '';
  34
  35   meta = {
  36     inherit (old.meta) license mainProgram;
  37     changelog = "https://github.com/jellyfin/jellyfin-ffmpeg/releases/tag/v${version}";
  38     description = "${old.meta.description} (Jellyfin fork)";
  39     homepage = "https://github.com/jellyfin/jellyfin-ffmpeg";
  40     maintainers = with lib.maintainers; [ justinas ];
  41     pkgConfigModules = [ "libavutil" ];
  42   };
  43 })