pkgs/by-name/nu/nulloy/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , which
   5 , pkg-config
   6 , zip
   7 , imagemagick
   8 , qt5
   9 , taglib
  10 , gst_all_1
  11 }:
  12
  13 stdenv.mkDerivation rec {
  14   pname = "nulloy";
  15   version = "0.9.9";
  16
  17   src = fetchFromGitHub {
  18     owner = "nulloy";
  19     repo = "nulloy";
  20     rev = version;
  21     hash = "sha256-vFg789vBV7ks+4YiWWl3u0/kQjzpAiX8dMfXU0hynDM=";
  22   };
  23
  24   nativeBuildInputs = [
  25     which # used by configure script
  26     pkg-config
  27     zip
  28     imagemagick
  29     qt5.qttools
  30     qt5.wrapQtAppsHook
  31   ];
  32
  33   buildInputs = [
  34     qt5.qtscript
  35     qt5.qtsvg
  36     taglib
  37   ] ++ (with gst_all_1; [
  38     gstreamer
  39     gst-plugins-base
  40     gst-plugins-good
  41     gst-plugins-bad
  42     gst-plugins-ugly
  43   ]);
  44
  45   prefixKey = "--prefix ";
  46
  47   enableParallelBuilding = true;
  48
  49   # FIXME: not added by gstreamer setup hook by default
  50   preFixup = ''
  51     qtWrapperArgs+=(
  52       --prefix GST_PLUGIN_SYSTEM_PATH_1_0 : "$GST_PLUGIN_SYSTEM_PATH_1_0"
  53     )
  54   '';
  55
  56   meta = with lib; {
  57     description = "Music player with a waveform progress bar";
  58     homepage = "https://nulloy.com";
  59     changelog = "https://github.com/nulloy/nulloy/blob/${src.rev}/ChangeLog";
  60     license = licenses.gpl3Only;
  61     mainProgram = "nulloy";
  62     maintainers = with maintainers; [ aleksana ];
  63     platforms = platforms.all;
  64     broken = stdenv.hostPlatform.isDarwin;
  65   };
  66 }