pkgs/by-name/eq/equicord/package.nix

   1 {
   2   fetchFromGitHub,
   3   git,
   4   lib,
   5   nodejs,
   6   pnpm_9,
   7   stdenv,
   8   buildWebExtension ? false,
   9 }:
  10 stdenv.mkDerivation (finalAttrs: {
  11   pname = "equicord";
  12   version = "1.10.4"; # from package.json
  13
  14   src = fetchFromGitHub {
  15     owner = "Equicord";
  16     repo = "Equicord";
  17     rev = "440b68ea82b6fd44bf5ec70b759a0207ee9f4ca7";
  18     hash = "sha256-9GIw8g2HZ6/5Lb4gtDyuBqZWi5YK5Uz0lo+u+LrIZwI=";
  19   };
  20
  21   pnpmDeps = pnpm_9.fetchDeps {
  22     inherit (finalAttrs) pname version src;
  23     hash = "sha256-kGLF6uIr0xxlB5LaSqKiBKESbmWN7PzDErrCmiT6vXA=";
  24   };
  25
  26   nativeBuildInputs = [
  27     git
  28     nodejs
  29     pnpm_9.configHook
  30   ];
  31
  32   env = {
  33     EQUICORD_REMOTE = "${finalAttrs.src.owner}/${finalAttrs.src.repo}";
  34     EQUICORD_HASH = "${finalAttrs.src.rev}";
  35   };
  36
  37   buildPhase = ''
  38     runHook preBuild
  39
  40     pnpm run ${if buildWebExtension then "buildWeb" else "build"} \
  41       -- --standalone --disable-updater
  42
  43     runHook postBuild
  44   '';
  45
  46   installPhase = ''
  47     runHook preInstall
  48
  49     cp -r dist/${lib.optionalString buildWebExtension "chromium-unpacked/"} $out
  50
  51     runHook postInstall
  52   '';
  53
  54   meta = {
  55     description = "The other cutest Discord client mod";
  56     homepage = "https://github.com/Equicord/Equicord";
  57     license = lib.licenses.gpl3Only;
  58     platforms = lib.platforms.linux;
  59     maintainers = [
  60       lib.maintainers.NotAShelf
  61     ];
  62   };
  63 })