pkgs/by-name/gr/graphicsmagick/imagemagick-compat.nix

   1 { lib
   2 , graphicsmagick
   3 , stdenvNoCC
   4 }:
   5
   6 stdenvNoCC.mkDerivation {
   7   pname = "graphicsmagick-imagemagick-compat";
   8   inherit (graphicsmagick) version;
   9
  10   outputs = [ "out" "man" ];
  11
  12   dontUnpack = true;
  13   dontBuild = true;
  14
  15   # TODO: symlink libraries?
  16   installPhase = let
  17     utilities = [
  18       "animate"
  19       "composite"
  20       "conjure"
  21       "convert"
  22       "display"
  23       "identify"
  24       "import"
  25       "mogrify"
  26       "montage"
  27     ];
  28     linkUtilityBin = utility: ''
  29       ln -s ${lib.getExe graphicsmagick} "$out/bin/${utility}"
  30     '';
  31     linkUtilityMan = utility: ''
  32       ln -s ${lib.getMan graphicsmagick}/share/man/man1/gm.1.gz "$man/share/man/man1/${utility}.1.gz"
  33     '';
  34   in ''
  35     runHook preInstall
  36
  37     mkdir -p "$out"/bin
  38     ${lib.concatStringsSep "\n" (map linkUtilityBin utilities)}
  39     mkdir -p "$man"/share/man/man1
  40     ${lib.concatStringsSep "\n" (map linkUtilityMan utilities)}
  41
  42     runHook postInstall
  43   '';
  44
  45   meta = graphicsmagick.meta // {
  46     description = "Repack of GraphicsMagick that provides compatibility with ImageMagick interfaces";
  47   };
  48 }