pkgs/by-name/kr/krita-plugin-gmic/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , cmake
   5 , extra-cmake-modules
   6 , fftw
   7 , krita
   8 , libsForQt5
   9 }:
  10
  11 stdenv.mkDerivation (finalAttrs: {
  12   pname = "krita-plugin-gmic";
  13   version = "3.2.4.1";
  14
  15   src = fetchFromGitHub {
  16     owner = "amyspark";
  17     repo = "gmic";
  18     rev = "v${finalAttrs.version}";
  19     hash = "sha256-SYE8kGvN7iD5OqiEEZpB/eRle67PrB5DojMC79qAQtg=";
  20   };
  21   sourceRoot = "${finalAttrs.src.name}/gmic-qt";
  22   dontWrapQtApps = true;
  23
  24   postPatch = ''
  25     patchShebangs \
  26       translations/filters/csv2ts.sh \
  27       translations/lrelease.sh
  28   '';
  29
  30   nativeBuildInputs = [ cmake extra-cmake-modules ];
  31
  32   buildInputs = [
  33     fftw
  34     krita.unwrapped
  35     libsForQt5.kcoreaddons
  36     libsForQt5.qttools
  37   ];
  38
  39   cmakeFlags = [
  40     (lib.cmakeFeature "GMIC_QT_HOST" "krita-plugin")
  41     # build krita's gmic instead of using the one from nixpkgs
  42     (lib.cmakeBool "ENABLE_SYSTEM_GMIC" false)
  43   ];
  44
  45   meta = with lib; {
  46     homepage = "https://github.com/amyspark/gmic";
  47     description = "GMic plugin for Krita";
  48     license = lib.licenses.cecill21;
  49     maintainers = with maintainers; [ lelgenio ];
  50   };
  51 })