pkgs/by-name/te/textlint-rule-max-comma/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   fetchYarnDeps,
   6   fixup-yarn-lock,
   7   nodejs,
   8   yarn,
   9   textlint,
  10   textlint-rule-max-comma,
  11 }:
  12
  13 stdenv.mkDerivation (finalAttrs: {
  14   pname = "textlint-rule-max-comma";
  15   version = "4.0.0";
  16
  17   src = fetchFromGitHub {
  18     owner = "textlint-rule";
  19     repo = "textlint-rule-max-comma";
  20     rev = "refs/tags/v${finalAttrs.version}";
  21     hash = "sha256-Sf7ehhEOcy1HdgnIra8darkucF6RebQQV/NfJtft/DA=";
  22   };
  23
  24   offlineCache = fetchYarnDeps {
  25     yarnLock = "${finalAttrs.src}/yarn.lock";
  26     hash = "sha256-jSsVQhvmc5mJ1gh6I5UaLvdz+HpaXI0fXFX0KCh01/c=";
  27   };
  28
  29   nativeBuildInputs = [
  30     fixup-yarn-lock
  31     nodejs
  32     yarn
  33   ];
  34
  35   configurePhase = ''
  36     runHook preConfigure
  37
  38     export HOME=$(mktemp -d)
  39     yarn config --offline set yarn-offline-mirror "$offlineCache"
  40     fixup-yarn-lock yarn.lock
  41     yarn --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive install
  42     patchShebangs node_modules
  43
  44     runHook postConfigure
  45   '';
  46
  47   buildPhase = ''
  48     runHook preBuild
  49
  50     yarn --offline build
  51
  52     runHook postBuild
  53   '';
  54
  55   installPhase = ''
  56     runHook preInstall
  57
  58     yarn --offline --production install
  59     rm -r test
  60     mkdir -p $out/lib/node_modules/textlint-rule-max-comma
  61     cp -r . $out/lib/node_modules/textlint-rule-max-comma/
  62
  63     runHook postInstall
  64   '';
  65
  66   passthru.tests = textlint.testPackages {
  67     rule = textlint-rule-max-comma;
  68     testFile = ./test.md;
  69   };
  70
  71   meta = {
  72     description = "Textlint rule is that limit maximum comma(,) count of sentence";
  73     homepage = "https://github.com/textlint-rule/textlint-rule-max-comma";
  74     changelog = "https://github.com/textlint-rule/textlint-rule-max-comma/releases/tag/${lib.removePrefix "refs/tags/" finalAttrs.src.rev}";
  75     license = lib.licenses.mit;
  76     maintainers = with lib.maintainers; [ natsukium ];
  77     platforms = textlint.meta.platforms;
  78   };
  79 })