pkgs/by-name/tk/tkdiff/package.nix

   1 { diffutils, fetchzip, lib, makeBinaryWrapper, stdenv, tk }:
   2
   3 stdenv.mkDerivation (finalAttrs: {
   4   pname = "tkdiff";
   5   version = "5.7";
   6
   7   src = fetchzip {
   8     url = "mirror://sourceforge/tkdiff/tkdiff-${builtins.replaceStrings ["."] ["-"] finalAttrs.version}.zip";
   9     hash = "sha256-ZndpolvaXoCAzR4KF+Bu7DJrXyB/C2H2lWp5FyzOc4M=";
  10   };
  11
  12   nativeBuildInputs = [ makeBinaryWrapper ];
  13
  14   installPhase = ''
  15     runHook preInstall
  16
  17     install -Dm755 -t $out/bin tkdiff
  18     wrapProgram $out/bin/tkdiff \
  19       --prefix PATH : ${lib.makeBinPath [ diffutils tk ]}
  20
  21     runHook postInstall
  22   '';
  23
  24   meta = {
  25     description = "Graphical front end to the diff program";
  26     homepage = "https://tkdiff.sourceforge.io/";
  27     license = lib.licenses.gpl2Plus;
  28     longDescription = ''
  29       TkDiff is a graphical front end to the diff program. It provides a
  30       side-by-side view of the differences between two text files, along
  31       with several innovative features such as diff bookmarks, a graphical
  32       map of differences for quick navigation, and a facility for slicing
  33       diff regions to achieve exactly the merge output desired.
  34     '';
  35     mainProgram = "tkdiff";
  36     maintainers = with lib.maintainers; [ mikaelfangel ];
  37     platforms = tk.meta.platforms;
  38   };
  39 })