pkgs/development/libraries/wasilibc/default.nix

   1 { stdenv
   2 , buildPackages
   3 , fetchFromGitHub
   4 , lib
   5 , firefox-unwrapped
   6 , firefox-esr-unwrapped
   7 }:
   8
   9 let
  10   pname = "wasilibc";
  11   version = "21";
  12 in
  13 stdenv.mkDerivation {
  14   inherit pname version;
  15
  16   src = buildPackages.fetchFromGitHub {
  17     owner = "WebAssembly";
  18     repo = "wasi-libc";
  19     rev = "refs/tags/wasi-sdk-${version}";
  20     hash = "sha256-1LsMpO29y79twVrUsuM/JvC7hK8O6Yey4Ard/S3Mvvc=";
  21     fetchSubmodules = true;
  22   };
  23
  24   outputs = [ "out" "dev" "share" ];
  25
  26   # clang-13: error: argument unused during compilation: '-rtlib=compiler-rt' [-Werror,-Wunused-command-line-argument]
  27   postPatch = ''
  28     substituteInPlace Makefile \
  29       --replace "-Werror" ""
  30   '';
  31
  32   preBuild = ''
  33     export SYSROOT_LIB=${builtins.placeholder "out"}/lib
  34     export SYSROOT_INC=${builtins.placeholder "dev"}/include
  35     export SYSROOT_SHARE=${builtins.placeholder "share"}/share
  36     mkdir -p "$SYSROOT_LIB" "$SYSROOT_INC" "$SYSROOT_SHARE"
  37     makeFlagsArray+=(
  38       "SYSROOT_LIB:=$SYSROOT_LIB"
  39       "SYSROOT_INC:=$SYSROOT_INC"
  40       "SYSROOT_SHARE:=$SYSROOT_SHARE"
  41       # https://bugzilla.mozilla.org/show_bug.cgi?id=1773200
  42       "BULK_MEMORY_SOURCES:="
  43     )
  44
  45   '';
  46
  47   enableParallelBuilding = true;
  48
  49   # We just build right into the install paths, per the `preBuild`.
  50   dontInstall = true;
  51
  52   preFixup = ''
  53     ln -s $share/share/undefined-symbols.txt $out/lib/wasi.imports
  54   '';
  55
  56   passthru.tests = {
  57     inherit firefox-unwrapped firefox-esr-unwrapped;
  58   };
  59
  60   meta = with lib; {
  61     changelog = "https://github.com/WebAssembly/wasi-sdk/releases/tag/wasi-sdk-${version}";
  62     description = "WASI libc implementation for WebAssembly";
  63     homepage = "https://wasi.dev";
  64     platforms = platforms.wasi;
  65     maintainers = with maintainers; [ matthewbauer rvolosatovs ];
  66     license = with licenses; [ asl20-llvm mit ];
  67   };
  68 }