pkgs/games/scummvm/default.nix

   1 { lib, stdenv, fetchFromGitHub, fetchpatch, nasm
   2 , alsa-lib, curl, flac, fluidsynth, freetype, libjpeg, libmad, libmpeg2, libogg, libtheora, libvorbis, libGLU, libGL, SDL2, zlib
   3 , Cocoa, AudioToolbox, Carbon, CoreMIDI, AudioUnit, cctools
   4 }:
   5
   6 stdenv.mkDerivation rec {
   7   pname = "scummvm";
   8   version = "2.8.1";
   9
  10   src = fetchFromGitHub {
  11     owner = "scummvm";
  12     repo = "scummvm";
  13     rev = "v${version}";
  14     hash = "sha256-8/q16MwHhbbmUxiwJOHkjNxrnBB4grMa7qw/n3KLvRc=";
  15   };
  16
  17   patches = [
  18     # Fix building with Freetype 2.13.3. Remove after next release.
  19     (fetchpatch {
  20       url = "https://github.com/scummvm/scummvm/commit/65977961b20ba97b1213b5267da0cb1efb49063b.patch?full_index=1";
  21       hash = "sha256-e5dJd3gP8OAD3hEJlvOhMemsNErCKTn7avlprApFig0=";
  22     })
  23   ];
  24
  25   nativeBuildInputs = [ nasm ];
  26
  27   buildInputs = lib.optionals stdenv.hostPlatform.isLinux [
  28     alsa-lib libGLU libGL
  29   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [
  30     Cocoa AudioToolbox Carbon CoreMIDI AudioUnit
  31   ] ++ [
  32     curl freetype flac fluidsynth libjpeg libmad libmpeg2 libogg libtheora libvorbis SDL2 zlib
  33   ];
  34
  35   dontDisableStatic = true;
  36
  37   enableParallelBuilding = true;
  38
  39   configurePlatforms = [ "host" ];
  40   configureFlags = [
  41     "--enable-release"
  42   ];
  43
  44   # They use 'install -s', that calls the native strip instead of the cross
  45   postConfigure = ''
  46     sed -i "s/-c -s/-c -s --strip-program=''${STRIP@Q}/" ports.mk
  47   '' + lib.optionalString stdenv.hostPlatform.isDarwin ''
  48     substituteInPlace config.mk \
  49       --replace x86_64-apple-darwin-ranlib ${cctools}/bin/ranlib \
  50       --replace aarch64-apple-darwin-ranlib ${cctools}/bin/ranlib
  51   '';
  52
  53   NIX_CFLAGS_COMPILE = [ "-fpermissive" ];
  54
  55   meta = with lib; {
  56     description = "Program to run certain classic graphical point-and-click adventure games (such as Monkey Island)";
  57     mainProgram = "scummvm";
  58     homepage = "https://www.scummvm.org/";
  59     license = licenses.gpl2Plus;
  60     maintainers = [ maintainers.peterhoeg ];
  61     platforms = platforms.unix;
  62   };
  63 }