pkgs/by-name/al/alp/package.nix

   1 { lib
   2 , buildGoModule
   3 , fetchFromGitHub
   4 , runCommand
   5 , alp
   6 }:
   7
   8 buildGoModule rec {
   9   pname = "alp";
  10   version = "1.1.18";
  11
  12   src = fetchFromGitHub {
  13     owner = "gernotfeichter";
  14     repo = "alp";
  15     rev = version;
  16     hash = "sha256-tE8qKNXLKvFcnDULVkJJ/EJyEsvATCk/3YFkZCmpHSo=";
  17   };
  18   vendorHash = "sha256-AHPVhtm6La7HWuxJfpxTsS5wFTUZUJoVyebLGYhNKTg=";
  19
  20   sourceRoot = "${src.name}/linux";
  21
  22   # Executing Go commands directly in checkPhase and buildPhase below,
  23   # because the default testsuite runs all go tests, some of which require docker.
  24   # Docker is too expensive for https://github.com/NixOS/ofborg.
  25   checkPhase = ''
  26     runHook preCheck
  27
  28     go test -run Test_main_init
  29
  30     runHook postCheck
  31   '';
  32
  33   buildPhase = ''
  34     runHook preBuild
  35
  36     go build -o $GOPATH/bin/alp main.go
  37
  38     runHook postBuild
  39   '';
  40
  41   passthru.tests = {
  42     test-version = runCommand "${pname}-test" {} ''
  43       ${alp}/bin/alp version > $out
  44       cat $out | grep '${version}'
  45     '';
  46   };
  47
  48   meta = with lib; {
  49     description = "Convenient authentication method that lets you use your android device as a key for your Linux machine";
  50     homepage = "https://github.com/gernotfeichter/alp";
  51     license = licenses.gpl2Only;
  52     mainProgram = "alp";
  53     maintainers = with maintainers; [ gernotfeichter ];
  54   };
  55 }