pkgs/by-name/br/browsers/package.nix

   1 {
   2   lib,
   3   rustPlatform,
   4   fetchFromGitHub,
   5   pkg-config,
   6   wrapGAppsHook3,
   7   atk,
   8   cairo,
   9   gdk-pixbuf,
  10   glib,
  11   gtk3,
  12   pango,
  13   stdenv,
  14   darwin,
  15 }:
  16
  17 rustPlatform.buildRustPackage rec {
  18   pname = "browsers";
  19   version = "0.6.0";
  20
  21   src = fetchFromGitHub {
  22     owner = "Browsers-software";
  23     repo = "browsers";
  24     rev = "refs/tags/${version}";
  25     hash = "sha256-qLqyv5XXG7cpW+/eNCWguqemT3G2BhnolntHi2zZJ0o=";
  26   };
  27
  28   cargoLock = {
  29     lockFile = ./Cargo.lock;
  30     outputHashes = {
  31       "druid-0.8.3" = "sha256-s9csjZ0ZimOrPnjJpPjrrMdNKAXFfroWHBPeR369Phk=";
  32       "rolling-file-0.2.0" = "sha256-3xeOSXFVVgeKRE39gtzTURt0OkKScQ4uwtvLl4CE3R4=";
  33     };
  34   };
  35
  36   nativeBuildInputs = [
  37     pkg-config
  38     wrapGAppsHook3
  39   ];
  40
  41   buildInputs =
  42     [
  43       atk
  44       cairo
  45       gdk-pixbuf
  46       glib
  47       gtk3
  48       pango
  49     ]
  50     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  51       darwin.apple_sdk.frameworks.AppKit
  52       darwin.apple_sdk.frameworks.CoreGraphics
  53       darwin.apple_sdk.frameworks.CoreText
  54       darwin.apple_sdk.frameworks.Foundation
  55     ];
  56
  57   postInstall = ''
  58     install -m 444 \
  59         -D extra/linux/dist/software.Browsers.template.desktop \
  60         -t $out/share/applications
  61     mv $out/share/applications/software.Browsers.template.desktop $out/share/applications/software.Browsers.desktop
  62     substituteInPlace \
  63         $out/share/applications/software.Browsers.desktop \
  64         --replace-fail 'Exec=€ExecCommand€' 'Exec=${pname} %u'
  65     cp -r resources $out
  66     for size in 16 32 128 256 512; do
  67       install -m 444 \
  68           -D resources/icons/"$size"x"$size"/software.Browsers.png \
  69           -t $out/share/icons/hicolor/"$size"x"$size"/apps
  70     done
  71   '';
  72
  73   meta = {
  74     description = "Open the right browser at the right time";
  75     homepage = "https://browsers.software";
  76     changelog = "https://github.com/Browsers-software/browsers/blob/${src.rev}/CHANGELOG.md";
  77     license = lib.licenses.mit;
  78     maintainers = with lib.maintainers; [ ravenz46 ];
  79     mainProgram = "browsers";
  80   };
  81 }