pkgs/by-name/es/espflash/package.nix

   1 {
   2   lib
   3 , rustPlatform
   4 , fetchFromGitHub
   5 , pkg-config
   6 , installShellFiles
   7 , udev
   8 , stdenv
   9 , CoreServices
  10 , Security
  11 , nix-update-script
  12 , openssl
  13 , SystemConfiguration
  14 }:
  15
  16 rustPlatform.buildRustPackage rec {
  17   pname = "espflash";
  18   version = "3.2.0";
  19
  20   src = fetchFromGitHub {
  21     owner = "esp-rs";
  22     repo = "espflash";
  23     rev = "refs/tags/v${version}";
  24     hash = "sha256-X9VTwXk/6zAkQb5P9Wz8Pt4oIt2xXfff9dhGb8wauG4=";
  25   };
  26
  27   nativeBuildInputs = [
  28     pkg-config
  29     installShellFiles
  30   ];
  31
  32   # Needed to get openssl-sys to use pkg-config.
  33   OPENSSL_NO_VENDOR = 1;
  34
  35   buildInputs = [ openssl ] ++ lib.optionals stdenv.hostPlatform.isLinux [
  36     udev
  37   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [
  38     CoreServices
  39     Security
  40     SystemConfiguration
  41   ];
  42
  43   cargoHash = "sha256-3xUDsznzIRlfGwVuIH1+Ub5tE/ST981KZS/2TAKaBAE=";
  44
  45   postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
  46     installShellCompletion --cmd espflash \
  47       --bash <($out/bin/espflash completions bash) \
  48       --zsh <($out/bin/espflash completions zsh) \
  49       --fish <($out/bin/espflash completions fish)
  50   '';
  51
  52   passthru.updateScript = nix-update-script { };
  53
  54   meta = with lib; {
  55     description = "Serial flasher utility for Espressif SoCs and modules based on esptool.py";
  56     homepage = "https://github.com/esp-rs/espflash";
  57     changelog = "https://github.com/esp-rs/espflash/blob/v${version}/CHANGELOG.md";
  58     mainProgram = "espflash";
  59     license = with licenses; [ mit /* or */ asl20 ];
  60     maintainers = with maintainers; [ matthiasbeyer ];
  61   };
  62 }