pkgs/by-name/up/upscayl/package.nix

   1 {
   2   appimageTools,
   3   fetchurl,
   4   lib,
   5   makeWrapper,
   6 }:
   7
   8 let
   9   pname = "upscayl";
  10   version = "2.11.5";
  11
  12   src = fetchurl {
  13     url = "https://github.com/upscayl/upscayl/releases/download/v${version}/upscayl-${version}-linux.AppImage";
  14     hash = "sha256-owxSm8t7rHM5ywJPp8sJQ5aAyNKgrbyJY6qFp78/UhM=";
  15   };
  16
  17   appimageContents = appimageTools.extractType2 {
  18     inherit pname version src;
  19   };
  20 in
  21 appimageTools.wrapType2 {
  22   inherit pname version src;
  23
  24   nativeBuildInputs = [
  25     makeWrapper
  26   ];
  27
  28   extraPkgs = pkgs: [
  29     pkgs.vulkan-headers
  30     pkgs.vulkan-loader
  31   ];
  32
  33   extraInstallCommands = ''
  34     mkdir -p $out/share/{applications,pixmaps}
  35
  36     cp ${appimageContents}/${pname}.desktop $out/share/applications/${pname}.desktop
  37     cp ${appimageContents}/${pname}.png $out/share/pixmaps/${pname}.png
  38
  39     substituteInPlace $out/share/applications/${pname}.desktop \
  40       --replace-fail 'Exec=AppRun --no-sandbox %U' 'Exec=${pname}'
  41
  42     wrapProgram $out/bin/${pname} \
  43       --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations}}"
  44   '';
  45
  46   meta = with lib; {
  47     description = "Free and Open Source AI Image Upscaler";
  48     homepage = "https://upscayl.github.io/";
  49     maintainers = with maintainers; [ icy-thought ];
  50     license = licenses.agpl3Plus;
  51     platforms = platforms.linux;
  52     mainProgram = "upscayl";
  53   };
  54 }