pkgs/tools/cd-dvd/ventoy/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , autoPatchelfHook
   5 , bash
   6 , copyDesktopItems
   7 , coreutils
   8 , cryptsetup
   9 , dosfstools
  10 , e2fsprogs
  11 , exfat
  12 , gawk
  13 , gnugrep
  14 , gnused
  15 , gtk3
  16 , hexdump
  17 , makeDesktopItem
  18 , makeWrapper
  19 , ntfs3g
  20 , parted
  21 , procps
  22 , util-linux
  23 , which
  24 , xfsprogs
  25 , xz
  26 , defaultGuiType ? ""
  27 , withCryptsetup ? false
  28 , withXfs ? false
  29 , withExt4 ? false
  30 , withNtfs ? false
  31 , withGtk3 ? false
  32 , withQt5 ? false
  33 , libsForQt5
  34 }:
  35
  36 assert lib.elem defaultGuiType [ "" "gtk3" "qt5" ];
  37 assert defaultGuiType == "gtk3" -> withGtk3;
  38 assert defaultGuiType == "qt5" -> withQt5;
  39
  40 let
  41   inherit (lib) optional optionalString;
  42   inherit (libsForQt5) qtbase wrapQtAppsHook;
  43   arch = {
  44     x86_64-linux = "x86_64";
  45     i686-linux = "i386";
  46     aarch64-linux = "aarch64";
  47     mipsel-linux = "mips64el";
  48   }.${stdenv.hostPlatform.system}
  49     or (throw "Unsupported platform ${stdenv.hostPlatform.system}");
  50 in
  51 stdenv.mkDerivation (finalAttrs: {
  52   pname = "ventoy";
  53   version = "1.0.96";
  54
  55   src =
  56     let
  57       inherit (finalAttrs) version;
  58     in
  59     fetchurl {
  60       url = "https://github.com/ventoy/Ventoy/releases/download/v${version}/ventoy-${version}-linux.tar.gz";
  61       hash = "sha256-eUpxfJQ0u3bpAXTUCKlMO/ViwKcBI59YFKJ3xGzSdcg=";
  62     };
  63
  64   patches = [
  65     ./000-nixos-sanitization.patch
  66   ];
  67
  68   postPatch = ''
  69     # Fix permissions.
  70     find -type f -name \*.sh -exec chmod a+x '{}' \;
  71
  72     # Fix path to log.
  73     sed -i 's:log\.txt:/var/log/ventoy\.log:g' \
  74         WebUI/static/js/languages.js tool/languages.json
  75   '';
  76
  77   nativeBuildInputs = [
  78     autoPatchelfHook
  79     makeWrapper
  80   ]
  81   ++ optional (withQt5 || withGtk3) copyDesktopItems
  82   ++ optional withQt5 wrapQtAppsHook;
  83
  84   buildInputs = [
  85     bash
  86     coreutils
  87     dosfstools
  88     exfat
  89     gawk
  90     gnugrep
  91     gnused
  92     hexdump
  93     parted
  94     procps
  95     util-linux
  96     which
  97     xz
  98   ]
  99   ++ optional withCryptsetup cryptsetup
 100   ++ optional withExt4 e2fsprogs
 101   ++ optional withGtk3 gtk3
 102   ++ optional withNtfs ntfs3g
 103   ++ optional withXfs xfsprogs
 104   ++ optional withQt5 qtbase;
 105
 106   desktopItems = [
 107     (makeDesktopItem {
 108       name = "Ventoy";
 109       desktopName = "Ventoy";
 110       comment = "Tool to create bootable USB drive for ISO/WIM/IMG/VHD(x)/EFI files";
 111       icon = "VentoyLogo";
 112       exec = "ventoy-gui";
 113       terminal = false;
 114       categories = [ "Utility" ];
 115       startupNotify = true;
 116     })
 117   ];
 118
 119   dontConfigure = true;
 120   dontBuild = true;
 121
 122   installPhase = ''
 123     runHook preInstall
 124
 125     # Setup variables
 126     local VENTOY_PATH="$out"/share/ventoy
 127     local ARCH='${arch}'
 128
 129     # Prepare
 130     cd tool/"$ARCH"
 131     rm ash* hexdump* mkexfatfs* mount.exfat-fuse* xzcat*
 132     for archive in *.xz; do
 133         xzcat "$archive" > "''${archive%.xz}"
 134         rm "$archive"
 135     done
 136     chmod a+x *
 137     cd -
 138
 139     # Cleanup.
 140     case "$ARCH" in
 141         x86_64) rm -r {tool/,VentoyGUI.}{i386,aarch64,mips64el};;
 142         i386) rm -r {tool/,VentoyGUI.}{x86_64,aarch64,mips64el};;
 143         aarch64) rm -r {tool/,VentoyGUI.}{x86_64,i386,mips64el};;
 144         mips64el) rm -r {tool/,VentoyGUI.}{x86_64,i386,aarch64};;
 145     esac
 146     rm README
 147     rm tool/"$ARCH"/Ventoy2Disk.gtk2 || true  # For aarch64 and mips64el.
 148
 149     # Copy from "$src" to "$out"
 150     mkdir -p "$out"/bin "$VENTOY_PATH"
 151     cp -r . "$VENTOY_PATH"
 152
 153     # Fill bin dir
 154     for f in Ventoy2Disk.sh_ventoy VentoyWeb.sh_ventoy-web \
 155              CreatePersistentImg.sh_ventoy-persistent \
 156              ExtendPersistentImg.sh_ventoy-extend-persistent \
 157              VentoyPlugson.sh_ventoy-plugson; do
 158         local bin="''${f%_*}" wrapper="''${f#*_}"
 159         makeWrapper "$VENTOY_PATH/$bin" "$out/bin/$wrapper" \
 160                     --prefix PATH : "${lib.makeBinPath finalAttrs.buildInputs}" \
 161                     --chdir "$VENTOY_PATH"
 162     done
 163   ''
 164   # VentoGUI uses the `ventoy_gui_type` file to determine the type of GUI.
 165   # See: https://github.com/ventoy/Ventoy/blob/v1.0.78/LinuxGUI/Ventoy2Disk/ventoy_gui.c#L1096
 166   + optionalString (withGtk3 || withQt5) ''
 167     echo "${defaultGuiType}" > "$VENTOY_PATH/ventoy_gui_type"
 168     makeWrapper "$VENTOY_PATH/VentoyGUI.$ARCH" "$out/bin/ventoy-gui" \
 169                 --prefix PATH : "${lib.makeBinPath finalAttrs.buildInputs}" \
 170                 --chdir "$VENTOY_PATH"
 171     mkdir "$out"/share/{applications,pixmaps}
 172     ln -s "$VENTOY_PATH"/WebUI/static/img/VentoyLogo.png "$out"/share/pixmaps/
 173   ''
 174   + optionalString (!withGtk3) ''
 175     rm "$VENTOY_PATH"/tool/{"$ARCH"/Ventoy2Disk.gtk3,VentoyGTK.glade}
 176   ''
 177   + optionalString (!withQt5) ''
 178     rm "$VENTOY_PATH/tool/$ARCH/Ventoy2Disk.qt5"
 179   ''
 180   + optionalString (!withGtk3 && !withQt5) ''
 181     rm "$VENTOY_PATH"/VentoyGUI.*
 182   '' +
 183   ''
 184
 185     runHook postInstall
 186   '';
 187
 188   meta = {
 189     homepage = "https://www.ventoy.net";
 190     description = "A New Bootable USB Solution";
 191     longDescription = ''
 192       Ventoy is an open source tool to create bootable USB drive for
 193       ISO/WIM/IMG/VHD(x)/EFI files.  With ventoy, you don't need to format the
 194       disk over and over, you just need to copy the ISO/WIM/IMG/VHD(x)/EFI files
 195       to the USB drive and boot them directly. You can copy many files at a time
 196       and ventoy will give you a boot menu to select them. You can also browse
 197       ISO/WIM/IMG/VHD(x)/EFI files in local disk and boot them. x86 Legacy
 198       BIOS, IA32 UEFI, x86_64 UEFI, ARM64 UEFI and MIPS64EL UEFI are supported
 199       in the same way.  Most type of OS supported
 200       (Windows/WinPE/Linux/ChromeOS/Unix/VMware/Xen...).  With ventoy you can
 201       also browse ISO/WIM/IMG/VHD(x)/EFI files in local disk and boot them.
 202       800+ image files are tested.  90%+ distros in DistroWatch supported.
 203     '';
 204     changelog = "https://www.ventoy.net/doc_news.html";
 205     license = lib.licenses.gpl3Plus;
 206     maintainers = with lib.maintainers; [ AndersonTorres ];
 207     platforms = [ "x86_64-linux" "i686-linux" "aarch64-linux" "mipsel-linux" ];
 208     sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
 209   };
 210 })