nixos/modules/programs/mininet.nix

   1 # Global configuration for mininet
   2 # kernel must have NETNS/VETH/SCHED
   3 { config, lib, pkgs, ... }:
   4
   5 with lib;
   6
   7 let
   8   cfg  = config.programs.mininet;
   9
  10   generatedPath = with pkgs; makeSearchPath "bin"  [
  11     iperf ethtool iproute2 socat
  12   ];
  13
  14   pyEnv = pkgs.python.withPackages(ps: [ ps.mininet-python ]);
  15
  16   mnexecWrapped = pkgs.runCommand "mnexec-wrapper"
  17     { nativeBuildInputs = [ pkgs.makeWrapper pkgs.pythonPackages.wrapPython ]; }
  18     ''
  19       makeWrapper ${pkgs.mininet}/bin/mnexec \
  20         $out/bin/mnexec \
  21         --prefix PATH : "${generatedPath}"
  22
  23       ln -s ${pyEnv}/bin/mn $out/bin/mn
  24
  25       # mn errors out without a telnet binary
  26       # pkgs.inetutils brings an undesired ifconfig into PATH see #43105
  27       ln -s ${pkgs.inetutils}/bin/telnet $out/bin/telnet
  28     '';
  29 in
  30 {
  31   options.programs.mininet.enable = mkEnableOption (lib.mdDoc "Mininet");
  32
  33   config = mkIf cfg.enable {
  34
  35     virtualisation.vswitch.enable = true;
  36
  37     environment.systemPackages = [ mnexecWrapped ];
  38   };
  39 }