nixos/modules/services/computing/boinc/client.nix

   1 {config, lib, pkgs, ...}:
   2
   3 with lib;
   4
   5 let
   6   cfg = config.services.boinc;
   7   allowRemoteGuiRpcFlag = optionalString cfg.allowRemoteGuiRpc "--allow_remote_gui_rpc";
   8
   9   fhsEnv = pkgs.buildFHSUserEnv {
  10     name = "boinc-fhs-env";
  11     targetPkgs = pkgs': [ cfg.package ] ++ cfg.extraEnvPackages;
  12     runScript = "/bin/boinc_client";
  13   };
  14   fhsEnvExecutable = "${fhsEnv}/bin/${fhsEnv.name}";
  15
  16 in
  17   {
  18     options.services.boinc = {
  19       enable = mkOption {
  20         type = types.bool;
  21         default = false;
  22         description = lib.mdDoc ''
  23           Whether to enable the BOINC distributed computing client. If this
  24           option is set to true, the boinc_client daemon will be run as a
  25           background service. The boinccmd command can be used to control the
  26           daemon.
  27         '';
  28       };
  29
  30       package = mkOption {
  31         type = types.package;
  32         default = pkgs.boinc;
  33         defaultText = literalExpression "pkgs.boinc";
  34         description = lib.mdDoc ''
  35           Which BOINC package to use.
  36         '';
  37       };
  38
  39       dataDir = mkOption {
  40         type = types.path;
  41         default = "/var/lib/boinc";
  42         description = lib.mdDoc ''
  43           The directory in which to store BOINC's configuration and data files.
  44         '';
  45       };
  46
  47       allowRemoteGuiRpc = mkOption {
  48         type = types.bool;
  49         default = false;
  50         description = lib.mdDoc ''
  51           If set to true, any remote host can connect to and control this BOINC
  52           client (subject to password authentication). If instead set to false,
  53           only the hosts listed in {var}`dataDir`/remote_hosts.cfg will be allowed to
  54           connect.
  55
  56           See also: <http://boinc.berkeley.edu/wiki/Controlling_BOINC_remotely#Remote_access>
  57         '';
  58       };
  59
  60       extraEnvPackages = mkOption {
  61         type = types.listOf types.package;
  62         default = [];
  63         example = literalExpression "[ pkgs.virtualbox ]";
  64         description = lib.mdDoc ''
  65           Additional packages to make available in the environment in which
  66           BOINC will run. Common choices are:
  67
  68           - {var}`pkgs.virtualbox`:
  69             The VirtualBox virtual machine framework. Required by some BOINC
  70             projects, such as ATLAS@home.
  71           - {var}`pkgs.ocl-icd`:
  72             OpenCL infrastructure library. Required by BOINC projects that
  73             use OpenCL, in addition to a device-specific OpenCL driver.
  74           - {var}`pkgs.linuxPackages.nvidia_x11`:
  75             Provides CUDA libraries. Required by BOINC projects that use
  76             CUDA. Note that this requires an NVIDIA graphics device to be
  77             present on the system.
  78
  79             Also provides OpenCL drivers for NVIDIA GPUs;
  80             {var}`pkgs.ocl-icd` is also needed in this case.
  81         '';
  82       };
  83     };
  84
  85     config = mkIf cfg.enable {
  86       environment.systemPackages = [cfg.package];
  87
  88       users.users.boinc = {
  89         group = "boinc";
  90         createHome = false;
  91         description = "BOINC Client";
  92         home = cfg.dataDir;
  93         isSystemUser = true;
  94       };
  95       users.groups.boinc = {};
  96
  97       systemd.tmpfiles.rules = [
  98         "d '${cfg.dataDir}' - boinc boinc - -"
  99       ];
 100
 101       systemd.services.boinc = {
 102         description = "BOINC Client";
 103         after = ["network.target"];
 104         wantedBy = ["multi-user.target"];
 105         script = ''
 106           ${fhsEnvExecutable} --dir ${cfg.dataDir} ${allowRemoteGuiRpcFlag}
 107         '';
 108         serviceConfig = {
 109           User = "boinc";
 110           Nice = 10;
 111         };
 112       };
 113     };
 114
 115     meta = {
 116       maintainers = with lib.maintainers; [kierdavis];
 117     };
 118   }