nixos/modules/services/hardware/usbmuxd.nix

   1 { config, lib, pkgs, ... }:
   2
   3 with lib;
   4
   5 let
   6
   7   defaultUserGroup = "usbmux";
   8   apple = "05ac";
   9
  10   cfg = config.services.usbmuxd;
  11
  12 in
  13
  14 {
  15   options.services.usbmuxd = {
  16     enable = mkOption {
  17       type = types.bool;
  18       default = false;
  19       description = lib.mdDoc ''
  20         Enable the usbmuxd ("USB multiplexing daemon") service. This daemon is
  21         in charge of multiplexing connections over USB to an iOS device. This is
  22         needed for transferring data from and to iOS devices (see ifuse). Also
  23         this may enable plug-n-play tethering for iPhones.
  24       '';
  25     };
  26
  27     user = mkOption {
  28       type = types.str;
  29       default = defaultUserGroup;
  30       description = lib.mdDoc ''
  31         The user usbmuxd should use to run after startup.
  32       '';
  33     };
  34
  35     group = mkOption {
  36       type = types.str;
  37       default = defaultUserGroup;
  38       description = lib.mdDoc ''
  39         The group usbmuxd should use to run after startup.
  40       '';
  41     };
  42   };
  43
  44   config = mkIf cfg.enable {
  45
  46     users.users = optionalAttrs (cfg.user == defaultUserGroup) {
  47       ${cfg.user} = {
  48         description = "usbmuxd user";
  49         group = cfg.group;
  50         isSystemUser = true;
  51       };
  52     };
  53
  54     users.groups = optionalAttrs (cfg.group == defaultUserGroup) {
  55       ${cfg.group} = { };
  56     };
  57
  58     # Give usbmuxd permission for Apple devices
  59     services.udev.extraRules = ''
  60       SUBSYSTEM=="usb", ATTR{idVendor}=="${apple}", GROUP="${cfg.group}"
  61     '';
  62
  63     systemd.services.usbmuxd = {
  64       description = "usbmuxd";
  65       wantedBy = [ "multi-user.target" ];
  66       unitConfig.Documentation = "man:usbmuxd(8)";
  67       serviceConfig = {
  68         # Trigger the udev rule manually. This doesn't require replugging the
  69         # device when first enabling the option to get it to work
  70         ExecStartPre = "${pkgs.udev}/bin/udevadm trigger -s usb -a idVendor=${apple}";
  71         ExecStart = "${pkgs.usbmuxd}/bin/usbmuxd -U ${cfg.user} -f";
  72       };
  73     };
  74
  75   };
  76 }