nixos/modules/services/search/meilisearch.nix

   1 { config, lib, pkgs, ... }:
   2
   3 with lib;
   4
   5 let
   6   cfg = config.services.meilisearch;
   7
   8 in
   9 {
  10
  11   meta.maintainers = with maintainers; [ Br1ght0ne happysalada ];
  12   # Don't edit the docbook xml directly, edit the md and generate it:
  13   # `pandoc meilisearch.md -t docbook --top-level-division=chapter --extract-media=media -f markdown+smart > meilisearch.xml`
  14   meta.doc = ./meilisearch.xml;
  15
  16   ###### interface
  17
  18   options.services.meilisearch = {
  19     enable = mkEnableOption (lib.mdDoc "MeiliSearch - a RESTful search API");
  20
  21     package = mkOption {
  22       description = lib.mdDoc "The package to use for meilisearch. Use this if you require specific features to be enabled. The default package has no features.";
  23       default = pkgs.meilisearch;
  24       defaultText = "pkgs.meilisearch";
  25       type = types.package;
  26     };
  27
  28     listenAddress = mkOption {
  29       description = lib.mdDoc "MeiliSearch listen address.";
  30       default = "127.0.0.1";
  31       type = types.str;
  32     };
  33
  34     listenPort = mkOption {
  35       description = lib.mdDoc "MeiliSearch port to listen on.";
  36       default = 7700;
  37       type = types.port;
  38     };
  39
  40     environment = mkOption {
  41       description = lib.mdDoc "Defines the running environment of MeiliSearch.";
  42       default = "development";
  43       type = types.enum [ "development" "production" ];
  44     };
  45
  46     # TODO change this to LoadCredentials once possible
  47     masterKeyEnvironmentFile = mkOption {
  48       description = lib.mdDoc ''
  49         Path to file which contains the master key.
  50         By doing so, all routes will be protected and will require a key to be accessed.
  51         If no master key is provided, all routes can be accessed without requiring any key.
  52         The format is the following:
  53         MEILI_MASTER_KEY=my_secret_key
  54       '';
  55       default = null;
  56       type = with types; nullOr path;
  57     };
  58
  59     noAnalytics = mkOption {
  60       description = lib.mdDoc ''
  61         Deactivates analytics.
  62         Analytics allow MeiliSearch to know how many users are using MeiliSearch,
  63         which versions and which platforms are used.
  64         This process is entirely anonymous.
  65       '';
  66       default = true;
  67       type = types.bool;
  68     };
  69
  70     logLevel = mkOption {
  71       description = lib.mdDoc ''
  72         Defines how much detail should be present in MeiliSearch's logs.
  73         MeiliSearch currently supports four log levels, listed in order of increasing verbosity:
  74         - 'ERROR': only log unexpected events indicating MeiliSearch is not functioning as expected
  75         - 'WARN:' log all unexpected events, regardless of their severity
  76         - 'INFO:' log all events. This is the default value
  77         - 'DEBUG': log all events and including detailed information on MeiliSearch's internal processes.
  78           Useful when diagnosing issues and debugging
  79       '';
  80       default = "INFO";
  81       type = types.str;
  82     };
  83
  84     maxIndexSize = mkOption {
  85       description = lib.mdDoc ''
  86         Sets the maximum size of the index.
  87         Value must be given in bytes or explicitly stating a base unit.
  88         For example, the default value can be written as 107374182400, '107.7Gb', or '107374 Mb'.
  89         Default is 100 GiB
  90       '';
  91       default = "107374182400";
  92       type = types.str;
  93     };
  94
  95     payloadSizeLimit = mkOption {
  96       description = lib.mdDoc ''
  97         Sets the maximum size of accepted JSON payloads.
  98         Value must be given in bytes or explicitly stating a base unit.
  99         For example, the default value can be written as 107374182400, '107.7Gb', or '107374 Mb'.
 100         Default is ~ 100 MB
 101       '';
 102       default = "104857600";
 103       type = types.str;
 104     };
 105
 106   };
 107
 108   ###### implementation
 109
 110   config = mkIf cfg.enable {
 111     systemd.services.meilisearch = {
 112       description = "MeiliSearch daemon";
 113       wantedBy = [ "multi-user.target" ];
 114       after = [ "network.target" ];
 115       environment = {
 116         MEILI_DB_PATH = "/var/lib/meilisearch";
 117         MEILI_HTTP_ADDR = "${cfg.listenAddress}:${toString cfg.listenPort}";
 118         MEILI_NO_ANALYTICS = toString cfg.noAnalytics;
 119         MEILI_ENV = cfg.environment;
 120         MEILI_DUMPS_DIR = "/var/lib/meilisearch/dumps";
 121         MEILI_LOG_LEVEL = cfg.logLevel;
 122         MEILI_MAX_INDEX_SIZE = cfg.maxIndexSize;
 123       };
 124       serviceConfig = {
 125         ExecStart = "${cfg.package}/bin/meilisearch";
 126         DynamicUser = true;
 127         StateDirectory = "meilisearch";
 128         EnvironmentFile = mkIf (cfg.masterKeyEnvironmentFile != null) cfg.masterKeyEnvironmentFile;
 129       };
 130     };
 131   };
 132 }