pkgs/applications/kde/kdenlive/default.nix

   1 { mkDerivation
   2 , lib
   3 , extra-cmake-modules
   4 , breeze-icons
   5 , breeze-qt5
   6 , kdoctools
   7 , kconfig
   8 , kcrash
   9 , kguiaddons
  10 , kiconthemes
  11 , ki18n
  12 , kinit
  13 , kdbusaddons
  14 , knotifications
  15 , knewstuff
  16 , karchive
  17 , knotifyconfig
  18 , kplotting
  19 , ktextwidgets
  20 , mlt
  21 , shared-mime-info
  22 , libv4l
  23 , kfilemetadata
  24 , ffmpeg-full
  25 , frei0r
  26 , phonon-backend-gstreamer
  27 , qtdeclarative
  28 , qtmultimedia
  29 , qtnetworkauth
  30 , qtquickcontrols2
  31 , qtscript
  32 , rttr
  33 , kpurpose
  34 , kdeclarative
  35 , wrapGAppsHook
  36 }:
  37
  38 mkDerivation {
  39   pname = "kdenlive";
  40   nativeBuildInputs = [
  41     extra-cmake-modules
  42     kdoctools
  43   ];
  44   buildInputs = [
  45     breeze-icons
  46     breeze-qt5
  47     kconfig
  48     kcrash
  49     kdbusaddons
  50     kfilemetadata
  51     kguiaddons
  52     ki18n
  53     kiconthemes
  54     kinit
  55     knotifications
  56     knewstuff
  57     karchive
  58     knotifyconfig
  59     kplotting
  60     ktextwidgets
  61     mlt
  62     phonon-backend-gstreamer
  63     qtdeclarative
  64     qtmultimedia
  65     qtnetworkauth
  66     qtquickcontrols2
  67     qtscript
  68     shared-mime-info
  69     libv4l
  70     ffmpeg-full
  71     frei0r
  72     rttr
  73     kpurpose
  74     kdeclarative
  75     wrapGAppsHook
  76   ];
  77   # Both MLT and FFMpeg paths must be set or Kdenlive will complain that it
  78   # doesn't find them. See:
  79   # https://github.com/NixOS/nixpkgs/issues/83885
  80   patches = [ ./mlt-path.patch ./ffmpeg-path.patch ];
  81   inherit mlt;
  82   ffmpeg = ffmpeg-full;
  83   postPatch =
  84     # Module Qt5::Concurrent must be included in `find_package` before it is used.
  85     ''
  86       sed -i CMakeLists.txt -e '/find_package(Qt5 REQUIRED/ s|)| Concurrent)|'
  87       substituteAllInPlace src/kdenlivesettings.kcfg
  88     '';
  89
  90   dontWrapGApps = true;
  91
  92   # Frei0r path needs to be set too or Kdenlive will complain. See:
  93   # https://github.com/NixOS/nixpkgs/issues/83885
  94   # https://github.com/NixOS/nixpkgs/issues/29614#issuecomment-488849325
  95   qtWrapperArgs = [
  96     "--set FREI0R_PATH ${frei0r}/lib/frei0r-1"
  97   ];
  98
  99   preFixup = ''
 100     qtWrapperArgs+=("''${gappsWrapperArgs[@]}")
 101   '';
 102
 103   meta = {
 104     homepage = "https://apps.kde.org/kdenlive/";
 105     description = "Video editor";
 106     license = with lib.licenses; [ gpl2Plus ];
 107     maintainers = with lib.maintainers; [ turion ];
 108   };
 109 }