pkgs/applications/misc/foxtrotgps/default.nix

   1 { lib, stdenv, fetchbzr, autoreconfHook, texinfo, help2man, imagemagick, pkg-config
   2 , curl, gnome2, gpsd, gtk2, wrapGAppsHook
   3 , intltool, libexif, python3Packages, sqlite }:
   4
   5 let
   6   srcs = {
   7     foxtrot = fetchbzr {
   8       url = "lp:foxtrotgps";
   9       rev = "331";
  10       sha256 = "sha256-/kJv6a3MzAzzwIl98Mqi7jrUJC1kDvouigf9kGtv868=";
  11     };
  12     screenshots = fetchbzr {
  13       url = "lp:foxtrotgps/screenshots";
  14       rev = "2";
  15       sha256 = "1sgysn3dhfhrv7rj7wf8f2119vmhc1s1zzsp4r3nlrr45d20wmsv";
  16     };
  17   };
  18 in stdenv.mkDerivation rec {
  19   pname = "foxtrotgps";
  20   version = "1.2.2+331";
  21
  22   # Pull directly from bzr because gpsd API version 9 is not supported on latest release
  23   src = srcs.foxtrot;
  24
  25   nativeBuildInputs = [
  26     pkg-config autoreconfHook texinfo help2man
  27     imagemagick wrapGAppsHook intltool
  28   ];
  29
  30   buildInputs = [
  31     curl.dev
  32     gnome2.libglade.dev
  33     gpsd
  34     gtk2.dev
  35     libexif
  36     sqlite.dev
  37     (python3Packages.python.withPackages (pythonPackages: with python3Packages;
  38     [ beautifulsoup4 feedparser sqlalchemy ]))
  39   ];
  40
  41   postUnpack = ''
  42     cp -R ${srcs.screenshots} $sourceRoot/doc/screenshots
  43     chmod -R u+w $sourceRoot/doc/screenshots
  44   '';
  45
  46   # Remove when foxtrotgps supports gpsd 3.23.1
  47   # Patch for compatibility with gpsd 3.23.1. This was added for foxtrotgps
  48   # 1.2.2+331. The command can be removed if the build of a newer version
  49   # succeeds without it.
  50   postPatch = ''
  51     substituteInPlace src/gps_functions.c --replace "STATUS_NO_FIX" "STATUS_UNK"
  52   '';
  53
  54   preConfigure = ''
  55     intltoolize --automake --copy --force
  56   '';
  57
  58   meta = with lib; {
  59     description = "GPS/GIS application optimized for small screens";
  60     longDescription = ''
  61       An easy to use, free & open-source GPS/GIS application that works well on
  62       small screens, and is especially suited to touch input. It spun off of
  63       tangoGPS in 2010 with a focus on cooperation and fostering community
  64       innovation.
  65     '';
  66     homepage = "https://www.foxtrotgps.org/";
  67     license = licenses.gpl2Plus;
  68     platforms = platforms.unix;
  69     maintainers = with maintainers; [ wucke13 ];
  70   };
  71 }