pkgs/applications/misc/fuzzel/default.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitea
   4 , pkg-config
   5 , meson
   6 , ninja
   7 , wayland-scanner
   8 , wayland
   9 , pixman
  10 , wayland-protocols
  11 , libxkbcommon
  12 , scdoc
  13 , tllist
  14 , fcft
  15 , enableCairo ? true
  16 , svgSupport ? true
  17 , pngSupport ? true
  18 # Optional dependencies
  19 , cairo
  20 , librsvg
  21 , libpng
  22 }:
  23
  24 assert svgSupport -> enableCairo;
  25
  26 stdenv.mkDerivation rec {
  27   pname = "fuzzel";
  28   version = "1.8.2";
  29
  30   src = fetchFromGitea {
  31     domain = "codeberg.org";
  32     owner = "dnkl";
  33     repo = "fuzzel";
  34     rev = version;
  35     sha256 = "sha256-5uXf5HfQ8bDQSMNCHHaC9sCX5P/D89T2ZOUiXTDx3bQ=";
  36   };
  37
  38   nativeBuildInputs = [
  39     pkg-config
  40     wayland-scanner
  41     meson
  42     ninja
  43     scdoc
  44   ];
  45
  46   buildInputs = [
  47     wayland
  48     pixman
  49     wayland-protocols
  50     libxkbcommon
  51     tllist
  52     fcft
  53   ] ++ lib.optional enableCairo cairo
  54     ++ lib.optional pngSupport libpng
  55     ++ lib.optional svgSupport librsvg;
  56
  57   mesonBuildType = "release";
  58
  59   mesonFlags = [
  60     "-Denable-cairo=${if enableCairo then "enabled" else "disabled"}"
  61     "-Dpng-backend=${if pngSupport then "libpng" else "none"}"
  62     "-Dsvg-backend=${if svgSupport then "librsvg" else "none"}"
  63   ];
  64
  65   meta = with lib; {
  66     description = "Wayland-native application launcher, similar to rofi’s drun mode";
  67     homepage = "https://codeberg.org/dnkl/fuzzel";
  68     license = licenses.mit;
  69     maintainers = with maintainers; [ fionera polykernel ];
  70     platforms = with platforms; linux;
  71     changelog = "https://codeberg.org/dnkl/fuzzel/releases/tag/${version}";
  72   };
  73 }