pkgs/applications/misc/join-desktop/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , alsa-lib
   5 , autoPatchelfHook
   6 , dpkg
   7 , gtk3
   8 , makeWrapper
   9 , mesa
  10 , nss
  11 , systemd
  12 , xorg
  13 }:
  14
  15 stdenv.mkDerivation rec {
  16   pname = "join-desktop";
  17   version = "1.1.2";
  18
  19   src = fetchurl {
  20     url = "https://github.com/joaomgcd/JoinDesktop/releases/download/v${version}/com.joaomgcd.join_${version}_amd64.deb";
  21     sha256 = "sha256-k1LX/HC3tfL4Raipo7wp/LnfrPa38x8NBeKRyHJ72CU=";
  22   };
  23
  24   nativeBuildInputs = [
  25     autoPatchelfHook
  26     dpkg
  27     makeWrapper
  28   ];
  29
  30   buildInputs = [
  31     alsa-lib
  32     gtk3
  33     mesa
  34     nss
  35     xorg.libXScrnSaver
  36     xorg.libXtst
  37   ];
  38
  39   unpackPhase = "dpkg-deb -x $src .";
  40
  41   runtimeDependencies = [
  42     (lib.getLib systemd)
  43     # TODO: check if they are required
  44     # libnotify
  45     # libappindicator
  46   ];
  47
  48   installPhase = ''
  49     runHook preInstall
  50
  51     mkdir -p $out/bin $out/share/join-desktop
  52
  53     mv usr/share/* $out/share
  54     mv opt/Join\ Desktop/* $out/share/join-desktop
  55
  56     ln -s $out/share/join-desktop/com.joaomgcd.join $out/bin/
  57
  58     substituteInPlace $out/share/applications/com.joaomgcd.join.desktop \
  59       --replace "/opt/Join Desktop/com.joaomgcd.join" "com.joaomgcd.join"
  60
  61     runHook postInstall
  62   '';
  63
  64   meta = with lib; {
  65     homepage = "https://github.com/joaomgcd/JoinDesktop/";
  66     description = "Desktop app for Join";
  67     sourceProvenance = with sourceTypes; [ binaryNativeCode ];
  68     # on https://joaoapps.com/join/desktop/ "Join Desktop is an open source app" but no license
  69     license = licenses.free;
  70     platforms = [ "x86_64-linux" ];
  71     maintainers = with maintainers; [ SuperSandro2000 ];
  72   };
  73
  74 }