pkgs/applications/misc/openrgb/default.nix

   1 { lib, mkDerivation, fetchFromGitLab, qmake, libusb1, hidapi, pkg-config, coreutils, mbedtls }:
   2
   3 mkDerivation rec {
   4   pname = "openrgb";
   5   version = "0.7";
   6
   7   src = fetchFromGitLab {
   8     owner = "CalcProgrammer1";
   9     repo = "OpenRGB";
  10     rev = "release_${version}";
  11     sha256 = "0xhfaz0b74nfnh7il2cz5c0338xlzay00g6hc2h3lsncarj8d5n7";
  12   };
  13
  14   nativeBuildInputs = [ qmake pkg-config ];
  15   buildInputs = [ libusb1 hidapi mbedtls ];
  16
  17   installPhase = ''
  18     runHook preInstall
  19
  20     mkdir -p $out/bin
  21     cp openrgb $out/bin
  22
  23     substituteInPlace 60-openrgb.rules \
  24       --replace /bin/chmod "${coreutils}/bin/chmod"
  25
  26     mkdir -p $out/etc/udev/rules.d
  27     cp 60-openrgb.rules $out/etc/udev/rules.d
  28
  29     install -Dm444 -t "$out/share/applications" qt/OpenRGB.desktop
  30     install -Dm444 -t "$out/share/icons/hicolor/128x128/apps" qt/OpenRGB.png
  31
  32     runHook postInstall
  33   '';
  34
  35   doInstallCheck = true;
  36   installCheckPhase = ''
  37     HOME=$TMPDIR $out/bin/openrgb --help > /dev/null
  38   '';
  39
  40   meta = with lib; {
  41     description = "Open source RGB lighting control";
  42     homepage = "https://gitlab.com/CalcProgrammer1/OpenRGB";
  43     maintainers = with maintainers; [ jonringer ];
  44     license = licenses.gpl2Plus;
  45     platforms = platforms.linux;
  46   };
  47 }