pkgs/applications/misc/sticky/default.nix

   1 { lib
   2 , python3
   3 , fetchFromGitHub
   4 , wrapGAppsHook
   5 , cinnamon
   6 , glib
   7 , gspell
   8 , gtk3
   9 , gobject-introspection
  10 , gitUpdater
  11 }:
  12
  13 python3.pkgs.buildPythonApplication rec {
  14   pname = "sticky";
  15   version = "1.12";
  16   format = "other";
  17
  18   src = fetchFromGitHub {
  19     owner = "linuxmint";
  20     repo = pname;
  21     rev = version;
  22     hash = "sha256-kAO8Qz4bTn3+YeIXAvPZ1SpKgn+g+rBgi9+TaqL1vOY=";
  23   };
  24
  25   postPatch = ''
  26     sed -i -e "s|/usr/share|$out/share|" usr/lib/sticky/*.py
  27   '';
  28
  29   nativeBuildInputs = [
  30     gobject-introspection
  31     wrapGAppsHook
  32   ];
  33
  34   buildInputs = [
  35     glib
  36     gobject-introspection
  37     cinnamon.xapp
  38     gspell
  39   ];
  40
  41   propagatedBuildInputs = with python3.pkgs; [
  42     pygobject3
  43     xapp
  44   ];
  45
  46   postBuild = ''
  47     glib-compile-schemas usr/share/glib-2.0/schemas
  48   '';
  49
  50   # hook for gobject-introspection doesn't like strictDeps
  51   # https://github.com/NixOS/nixpkgs/issues/56943
  52   strictDeps = false;
  53
  54   # no tests
  55   doCheck = false;
  56
  57   dontWrapGApps = true;
  58
  59   installPhase = ''
  60     runHook preInstall
  61
  62     mkdir -p $out/bin
  63     mv usr/lib $out
  64     mv usr/share $out
  65     patchShebangs $out/lib/sticky
  66     mv $out/lib/sticky/sticky.py $out/bin/sticky
  67     sed -i -e "1aimport sys;sys.path.append('$out/lib/sticky')" $out/bin/sticky
  68
  69     runHook postInstall
  70   '';
  71
  72   # Arguments to be passed to `makeWrapper`, only used by buildPython*
  73   preFixup = ''
  74     makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
  75   '';
  76
  77   passthru = {
  78     updateScript = gitUpdater {
  79       ignoredVersions = ''master.*'';
  80     };
  81   };
  82
  83   meta = with lib; {
  84     description = "A sticky notes app for the linux desktop";
  85     homepage = "https://github.com/linuxmint/sticky";
  86     license = licenses.gpl2Only;
  87     platforms = platforms.linux;
  88     maintainers = with maintainers; [ linsui bobby285271 ];
  89   };
  90 }