pkgs/applications/misc/tandoor-recipes/frontend.nix

   1 { stdenv, fetchYarnDeps, fixup_yarn_lock, callPackage, nodejs-16_x }:
   2 let
   3   common = callPackage ./common.nix { };
   4 in
   5 stdenv.mkDerivation {
   6   pname = "tandoor-recipes-frontend";
   7   inherit (common) version;
   8
   9   src = "${common.src}/vue";
  10
  11   yarnOfflineCache = fetchYarnDeps {
  12     yarnLock = "${common.src}/vue/yarn.lock";
  13     sha256 = common.yarnSha256;
  14   };
  15
  16   nativeBuildInputs = [
  17     fixup_yarn_lock
  18     # Use Node JS 16 because of @achrinza/node-ipc@9.2.2
  19     nodejs-16_x
  20     nodejs-16_x.pkgs.yarn
  21   ];
  22
  23   configurePhase = ''
  24     runHook preConfigure
  25
  26     export HOME=$(mktemp -d)
  27     yarn config --offline set yarn-offline-mirror "$yarnOfflineCache"
  28     fixup_yarn_lock yarn.lock
  29     command -v yarn
  30     yarn install --frozen-lockfile --offline --no-progress --non-interactive
  31     patchShebangs node_modules/
  32
  33     runHook postConfigure
  34   '';
  35
  36   buildPhase = ''
  37     runHook preBuild
  38
  39     yarn --offline run build
  40
  41     runHook postBuild
  42   '';
  43
  44   installPhase = ''
  45     runHook preInstall
  46
  47     cp -R ../cookbook/static/vue/ $out
  48     cp webpack-stats.json $out
  49     echo "${common.version}" > "$out/version"
  50
  51     runHook postInstall
  52   '';
  53
  54   meta = common.meta // {
  55     description = "Tandoor Recipes frontend";
  56   };
  57 }