pkgs/applications/plasma-mobile/default.nix

   1 /*
   2
   3 # New packages
   4
   5 READ THIS FIRST
   6
   7 This module is for official packages in the Plasma Mobile Gear. All
   8 available packages are listed in `./srcs.nix`, although some are not yet
   9 packaged in Nixpkgs.
  10
  11 IF YOUR PACKAGE IS NOT LISTED IN `./srcs.nix`, IT DOES NOT GO HERE.
  12
  13 See also `pkgs/applications/kde` as this is what this is based on.
  14
  15 # Updates
  16
  17 1. Update the URL in `./fetch.sh`.
  18 2. Run `./maintainers/scripts/fetch-kde-qt.sh pkgs/applications/plasma-mobile`
  19    from the top of the Nixpkgs tree.
  20 3. Use `nox-review wip` to check that everything builds.
  21 4. Commit the changes and open a pull request.
  22
  23 */
  24
  25 { lib
  26 , libsForQt5
  27 , fetchurl
  28 }:
  29
  30 let
  31   minQtVersion = "5.15";
  32   broken = lib.versionOlder libsForQt5.qtbase.version minQtVersion;
  33
  34   mirror = "mirror://kde";
  35   srcs = import ./srcs.nix { inherit fetchurl mirror; };
  36
  37   mkDerivation = args:
  38     let
  39       inherit (args) pname;
  40       inherit (srcs.${pname}) src version;
  41       mkDerivation =
  42         libsForQt5.callPackage ({ mkDerivation }: mkDerivation) {};
  43     in
  44       mkDerivation (args // {
  45         inherit pname version src;
  46
  47         outputs = args.outputs or [ "out" ];
  48
  49         meta =
  50           let meta = args.meta or {}; in
  51           meta // {
  52             homepage = meta.homepage or "https://www.plasma-mobile.org/";
  53             platforms = meta.platforms or lib.platforms.linux;
  54             broken = meta.broken or broken;
  55           };
  56       });
  57
  58   packages = self: with self;
  59     let
  60       callPackage = self.newScope {
  61         inherit mkDerivation;
  62       };
  63     in {
  64       alligator = callPackage ./alligator.nix {};
  65       angelfish = callPackage ./angelfish.nix { inherit srcs; };
  66       audiotube = callPackage ./audiotube.nix {};
  67       calindori = callPackage ./calindori.nix {};
  68       kalk = callPackage ./kalk.nix {};
  69       kasts = callPackage ./kasts.nix {};
  70       kclock = callPackage ./kclock.nix {};
  71       keysmith = callPackage ./keysmith.nix {};
  72       koko = callPackage ./koko.nix {};
  73       krecorder = callPackage ./krecorder.nix {};
  74       ktrip = callPackage ./ktrip.nix {};
  75       kweather = callPackage ./kweather.nix {};
  76       neochat = callPackage ./neochat.nix { inherit srcs; };
  77       plasma-dialer = callPackage ./plasma-dialer.nix {};
  78       plasma-phonebook = callPackage ./plasma-phonebook.nix {};
  79       plasma-settings = callPackage ./plasma-settings.nix {};
  80       plasmatube = callPackage ./plasmatube.nix {};
  81       spacebar = callPackage ./spacebar.nix { inherit srcs; };
  82     };
  83
  84 in lib.makeScope libsForQt5.newScope packages