pkgs/development/libraries/SDL2/default.nix

   1 { lib
   2 , stdenv
   3 , config
   4 , fetchurl
   5 , pkg-config
   6 , libGLSupported ? lib.elem stdenv.hostPlatform.system lib.platforms.mesaPlatforms
   7 , openglSupport ? libGLSupported
   8 , libGL
   9 , alsaSupport ? stdenv.isLinux && !stdenv.hostPlatform.isAndroid
  10 , alsa-lib
  11 , x11Support ? !stdenv.targetPlatform.isWindows && !stdenv.hostPlatform.isAndroid
  12 , libX11
  13 , xorgproto
  14 , libICE
  15 , libXi
  16 , libXScrnSaver
  17 , libXcursor
  18 , libXinerama
  19 , libXext
  20 , libXxf86vm
  21 , libXrandr
  22 , waylandSupport ? stdenv.isLinux && !stdenv.hostPlatform.isAndroid
  23 , wayland
  24 , wayland-protocols
  25 , wayland-scanner
  26 , drmSupport ? stdenv.isLinux && !stdenv.hostPlatform.isAndroid
  27 , libdrm
  28 , mesa
  29 , libxkbcommon
  30 , dbusSupport ? stdenv.isLinux && !stdenv.hostPlatform.isAndroid
  31 , dbus
  32 , udevSupport ? stdenv.isLinux && !stdenv.hostPlatform.isAndroid
  33 , udev
  34 , ibusSupport ? false
  35 , ibus
  36 , fcitxSupport ? false
  37 , fcitx
  38 , libdecorSupport ? stdenv.isLinux && !stdenv.hostPlatform.isAndroid
  39 , libdecor
  40 , pipewireSupport ? stdenv.isLinux && !stdenv.hostPlatform.isAndroid
  41 , pipewire # NOTE: must be built with SDL2 without pipewire support
  42 , pulseaudioSupport ? config.pulseaudio or stdenv.isLinux && !stdenv.hostPlatform.isAndroid
  43 , libpulseaudio
  44 , AudioUnit
  45 , Cocoa
  46 , CoreAudio
  47 , CoreServices
  48 , ForceFeedback
  49 , OpenGL
  50 , audiofile
  51 , libiconv
  52 , withStatic ? false
  53 }:
  54
  55 # NOTE: When editing this expression see if the same change applies to
  56 # SDL expression too
  57
  58 with lib;
  59
  60 stdenv.mkDerivation rec {
  61   pname = "SDL2";
  62   version = "2.24.2";
  63
  64   src = fetchurl {
  65     url = "https://www.libsdl.org/release/${pname}-${version}.tar.gz";
  66     sha256 = "sha256-s17wqAKwnZDtOt0NysDpWCCAQgKRT1u3sP63EPGhMp8=";
  67   };
  68   dontDisableStatic = if withStatic then 1 else 0;
  69   outputs = [ "out" "dev" ];
  70   outputBin = "dev"; # sdl-config
  71
  72   patches = [
  73     # `sdl2-config --cflags` from Nixpkgs returns include path to just SDL2.
  74     # On a normal distro this is enough for includes from all SDL2* packages to work,
  75     # but on NixOS they're spread across different paths.
  76     # This patch + the setup-hook will ensure that `sdl2-config --cflags` works correctly.
  77     ./find-headers.patch
  78   ];
  79
  80   postPatch = ''
  81     # Fix running wayland-scanner for the build platform when cross-compiling.
  82     # See comment here: https://github.com/libsdl-org/SDL/issues/4860#issuecomment-1119003545
  83     substituteInPlace configure \
  84       --replace '$(WAYLAND_SCANNER)' 'wayland-scanner'
  85   '';
  86
  87   strictDeps = true;
  88
  89   depsBuildBuild = [ pkg-config ];
  90
  91   nativeBuildInputs = [ pkg-config ] ++ optionals waylandSupport [ wayland wayland-scanner ];
  92
  93   propagatedBuildInputs = dlopenPropagatedBuildInputs;
  94
  95   dlopenPropagatedBuildInputs = [ ]
  96     # Propagated for #include <GLES/gl.h> in SDL_opengles.h.
  97     ++ optional openglSupport libGL
  98     # Propagated for #include <X11/Xlib.h> and <X11/Xatom.h> in SDL_syswm.h.
  99     ++ optionals x11Support [ libX11 xorgproto ];
 100
 101   dlopenBuildInputs = optionals alsaSupport [ alsa-lib audiofile ]
 102     ++ optional dbusSupport dbus
 103     ++ optional libdecorSupport libdecor
 104     ++ optional pipewireSupport pipewire
 105     ++ optional pulseaudioSupport libpulseaudio
 106     ++ optional udevSupport udev
 107     ++ optionals waylandSupport [ wayland wayland-protocols libxkbcommon ]
 108     ++ optionals x11Support [ libICE libXi libXScrnSaver libXcursor libXinerama libXext libXrandr libXxf86vm ]
 109     ++ optionals drmSupport [ libdrm mesa ];
 110
 111   buildInputs = [ libiconv ]
 112     ++ dlopenBuildInputs
 113     ++ optional ibusSupport ibus
 114     ++ optional fcitxSupport fcitx
 115     ++ optionals stdenv.isDarwin [ AudioUnit Cocoa CoreAudio CoreServices ForceFeedback OpenGL ];
 116
 117   enableParallelBuilding = true;
 118
 119   configureFlags = [
 120     "--disable-oss"
 121   ] ++ optional (!x11Support) "--without-x"
 122   ++ optional alsaSupport "--with-alsa-prefix=${alsa-lib.out}/lib"
 123   ++ optional stdenv.targetPlatform.isWindows "--disable-video-opengles"
 124   ++ optional stdenv.isDarwin "--disable-sdltest";
 125
 126   # We remove libtool .la files when static libs are requested,
 127   # because they make the builds of downstream libs like `SDL_tff`
 128   # fail with `cannot find -lXext, `-lXcursor` etc. linker errors
 129   # because the `.la` files are not pruned if static libs exist
 130   # (see https://github.com/NixOS/nixpkgs/commit/fd97db43bcb05e37f6bb77f363f1e1e239d9de53)
 131   # and they also don't carry the necessary `-L` paths of their
 132   # X11 dependencies.
 133   # For static linking, it is better to rely on `pkg-config` `.pc`
 134   # files.
 135   postInstall = ''
 136     if [ "$dontDisableStatic" -eq "1" ]; then
 137       rm $out/lib/*.la
 138     else
 139       rm $out/lib/*.a
 140     fi
 141     moveToOutput bin/sdl2-config "$dev"
 142   '';
 143
 144   # SDL is weird in that instead of just dynamically linking with
 145   # libraries when you `--enable-*` (or when `configure` finds) them
 146   # it `dlopen`s them at runtime. In principle, this means it can
 147   # ignore any missing optional dependencies like alsa, pulseaudio,
 148   # some x11 libs, wayland, etc if they are missing on the system
 149   # and/or work with wide array of versions of said libraries. In
 150   # nixpkgs, however, we don't need any of that. Moreover, since we
 151   # don't have a global ld-cache we have to stuff all the propagated
 152   # libraries into rpath by hand or else some applications that use
 153   # SDL API that requires said libraries will fail to start.
 154   #
 155   # You can grep SDL sources with `grep -rE 'SDL_(NAME|.*_SYM)'` to
 156   # list the symbols used in this way.
 157   postFixup =
 158     let
 159       rpath = makeLibraryPath (dlopenPropagatedBuildInputs ++ dlopenBuildInputs);
 160     in
 161     optionalString (stdenv.hostPlatform.extensions.sharedLibrary == ".so") ''
 162       for lib in $out/lib/*.so* ; do
 163         if ! [[ -L "$lib" ]]; then
 164           patchelf --set-rpath "$(patchelf --print-rpath $lib):${rpath}" "$lib"
 165         fi
 166       done
 167     '';
 168
 169   setupHook = ./setup-hook.sh;
 170
 171   passthru = { inherit openglSupport; };
 172
 173   meta = with lib; {
 174     description = "A cross-platform multimedia library";
 175     homepage = "http://www.libsdl.org/";
 176     license = licenses.zlib;
 177     platforms = platforms.all;
 178     maintainers = with maintainers; [ cpages ];
 179   };
 180 }