pkgs/development/libraries/accountsservice/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , substituteAll
   5 , pkg-config
   6 , glib
   7 , shadow
   8 , gobject-introspection
   9 , polkit
  10 , systemd
  11 , coreutils
  12 , meson
  13 , mesonEmulatorHook
  14 , dbus
  15 , ninja
  16 , python3
  17 , vala
  18 , gettext
  19 , libxcrypt
  20 }:
  21
  22 stdenv.mkDerivation rec {
  23   pname = "accountsservice";
  24   version = "22.08.8";
  25
  26   outputs = [ "out" "dev" ];
  27
  28   src = fetchurl {
  29     url = "https://www.freedesktop.org/software/accountsservice/accountsservice-${version}.tar.xz";
  30     sha256 = "kJmXp2kZ/n3BOKmgHOpwvWItWpMtvJ+xMBARMCOno5E=";
  31   };
  32
  33   patches = [
  34     # Hardcode dependency paths.
  35     (substituteAll {
  36       src = ./fix-paths.patch;
  37       inherit shadow coreutils;
  38     })
  39
  40     # Do not try to create directories in /var, that will not work in Nix sandbox.
  41     ./no-create-dirs.patch
  42
  43     # Disable mutating D-Bus methods with immutable /etc.
  44     ./Disable-methods-that-change-files-in-etc.patch
  45
  46     # Do not ignore third-party (e.g Pantheon) extensions not matching FHS path scheme.
  47     # Fixes https://github.com/NixOS/nixpkgs/issues/72396
  48     ./drop-prefix-check-extensions.patch
  49   ];
  50
  51   nativeBuildInputs = [
  52     gettext
  53     gobject-introspection
  54     meson
  55     ninja
  56     pkg-config
  57     python3
  58     vala
  59   ] ++ lib.optionals (!stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
  60     #  meson.build:88:2: ERROR: Can not run test applications in this cross environment.
  61     mesonEmulatorHook
  62   ];
  63
  64   buildInputs = [
  65     gobject-introspection
  66     dbus
  67     glib
  68     polkit
  69     systemd
  70     libxcrypt
  71   ];
  72
  73   mesonFlags = [
  74     "-Dadmin_group=wheel"
  75     "-Dlocalstatedir=/var"
  76     "-Dsystemdsystemunitdir=${placeholder "out"}/etc/systemd/system"
  77   ];
  78
  79   postPatch = ''
  80     chmod +x meson_post_install.py
  81     patchShebangs meson_post_install.py
  82   '';
  83
  84   meta = with lib; {
  85     description = "D-Bus interface for user account query and manipulation";
  86     homepage = "https://www.freedesktop.org/wiki/Software/AccountsService";
  87     license = licenses.gpl3Plus;
  88     maintainers = teams.freedesktop.members ++ (with maintainers; [ pSub ]);
  89     platforms = platforms.linux;
  90   };
  91 }