pkgs/development/libraries/fontconfig/default.nix

   1 { stdenv
   2 , lib
   3 , fetchurl
   4 , pkg-config
   5 , python3
   6 , freetype
   7 , expat
   8 , libxslt
   9 , gperf
  10 , dejavu_fonts
  11 , autoreconfHook
  12 , CoreFoundation
  13 }:
  14
  15 stdenv.mkDerivation rec {
  16   pname = "fontconfig";
  17   version = "2.14.0";
  18
  19   outputs = [ "bin" "dev" "lib" "out" ]; # $out contains all the config
  20
  21   src = fetchurl {
  22     url = "https://www.freedesktop.org/software/fontconfig/release/${pname}-${version}.tar.xz";
  23     sha256 = "3L64TJx0u/2xM9U1/hx77cnyIhqNrzkUuYTETFIOm6w=";
  24   };
  25
  26   nativeBuildInputs = [
  27     autoreconfHook
  28     gperf
  29     libxslt
  30     pkg-config
  31     python3
  32   ];
  33
  34   buildInputs = [
  35     expat
  36   ] ++ lib.optional stdenv.isDarwin CoreFoundation;
  37
  38   propagatedBuildInputs = [
  39     freetype
  40   ];
  41
  42   postPatch = ''
  43     # Requires networking.
  44     sed -i '/check_PROGRAMS += test-crbug1004254/d' test/Makefile.am
  45   '';
  46
  47   configureFlags = [
  48     "--sysconfdir=/etc"
  49     "--with-arch=${stdenv.hostPlatform.parsed.cpu.name}"
  50     "--with-cache-dir=/var/cache/fontconfig" # otherwise the fallback is in $out/
  51     # just <1MB; this is what you get when loading config fails for some reason
  52     "--with-default-fonts=${dejavu_fonts.minimal}"
  53   ] ++ lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
  54     "--with-arch=${stdenv.hostPlatform.parsed.cpu.name}"
  55   ];
  56
  57   enableParallelBuilding = true;
  58
  59   doCheck = true;
  60
  61   installFlags = [
  62     # Don't try to write to /var/cache/fontconfig at install time.
  63     "fc_cachedir=$(TMPDIR)/dummy"
  64     "RUN_FC_CACHE_TEST=false"
  65     "sysconfdir=${placeholder "out"}/etc"
  66   ];
  67
  68   postInstall = ''
  69     cd "$out/etc/fonts"
  70     xsltproc --stringparam fontDirectories "${dejavu_fonts.minimal}" \
  71       --path $out/share/xml/fontconfig \
  72       ${./make-fonts-conf.xsl} $out/etc/fonts/fonts.conf \
  73       > fonts.conf.tmp
  74     mv fonts.conf.tmp $out/etc/fonts/fonts.conf
  75     # We don't keep section 3 of the manpages, as they are quite large and
  76     # probably not so useful.
  77     rm -r $bin/share/man/man3
  78   '';
  79
  80   meta = with lib; {
  81     description = "A library for font customization and configuration";
  82     homepage = "http://fontconfig.org/";
  83     license = licenses.bsd2; # custom but very bsd-like
  84     platforms = platforms.all;
  85     maintainers = with maintainers; teams.freedesktop.members ++ [ ];
  86   };
  87 }