pkgs/development/libraries/jellyfin-ffmpeg/default.nix

   1 { ffmpeg_5-full
   2 , nv-codec-headers-11
   3 , fetchFromGitHub
   4 , lib
   5 }:
   6
   7 (ffmpeg_5-full.override {
   8   nv-codec-headers = nv-codec-headers-11;
   9 }).overrideAttrs (old: rec {
  10   pname = "jellyfin-ffmpeg";
  11   version = "5.1.2-4";
  12
  13   src = fetchFromGitHub {
  14     owner = "jellyfin";
  15     repo = "jellyfin-ffmpeg";
  16     rev = "v${version}";
  17     sha256 = "sha256-yzaS50sPgyRRLnvzaOiKOEaHKL3Yuf89KsHyPebjoL8=";
  18   };
  19
  20   configureFlags = old.configureFlags ++ [
  21     "--disable-ptx-compression" # https://github.com/jellyfin/jellyfin/issues/7944#issuecomment-1156880067
  22   ];
  23
  24   postPatch = ''
  25     for file in $(cat debian/patches/series); do
  26       patch -p1 < debian/patches/$file
  27     done
  28
  29     ${old.postPatch or ""}
  30   '';
  31
  32   meta = with lib; {
  33     description = "${old.meta.description} (Jellyfin fork)";
  34     homepage = "https://github.com/jellyfin/jellyfin-ffmpeg";
  35     license = licenses.gpl3;
  36     maintainers = with maintainers; [ justinas ];
  37   };
  38 })