pkgs/development/libraries/libarchive/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , acl
   5 , attr
   6 , autoreconfHook
   7 , bzip2
   8 , e2fsprogs
   9 , lzo
  10 , openssl
  11 , pkg-config
  12 , sharutils
  13 , xz
  14 , zlib
  15 , zstd
  16 # Optional but increases closure only negligibly. Also, while libxml2 builds
  17 # fine on windows, libarchive has trouble linking windows things it depends on
  18 # for some reason.
  19 , xarSupport ? stdenv.hostPlatform.isUnix, libxml2
  20
  21 # for passthru.tests
  22 , cmake
  23 , nix
  24 , samba
  25 }:
  26
  27 assert xarSupport -> libxml2 != null;
  28
  29 stdenv.mkDerivation rec {
  30   pname = "libarchive";
  31   version = "3.6.1";
  32
  33   src = fetchFromGitHub {
  34     owner = "libarchive";
  35     repo = "libarchive";
  36     rev = "v${version}";
  37     hash = "sha256-G4wL5DDbX0FqaA4cnOlVLZ25ObN8dNsRtxyas29tpDA=";
  38   };
  39
  40   postPatch = ''
  41     substituteInPlace Makefile.am --replace '/bin/pwd' "$(type -P pwd)"
  42
  43     declare -a skip_test_paths=(
  44       # test won't work in nix sandbox
  45       'libarchive/test/test_write_disk_perms.c'
  46       # can't be sure builder will have sparse-capable fs
  47       'libarchive/test/test_sparse_basic.c'
  48       # can't even be sure builder will have hardlink-capable fs
  49       'libarchive/test/test_write_disk_hardlink.c'
  50       # access-time-related tests flakey on some systems
  51       'cpio/test/test_option_a.c'
  52       'cpio/test/test_option_t.c'
  53     )
  54
  55     for test_path in "''${skip_test_paths[@]}" ; do
  56       substituteInPlace Makefile.am --replace "$test_path" ""
  57       rm "$test_path"
  58     done
  59   '';
  60
  61   outputs = [ "out" "lib" "dev" ];
  62
  63   nativeBuildInputs = [
  64     autoreconfHook
  65     pkg-config
  66   ];
  67
  68   buildInputs =  [
  69     bzip2
  70     lzo
  71     openssl
  72     xz
  73     zlib
  74     zstd
  75   ] ++ lib.optional stdenv.hostPlatform.isUnix sharutils
  76     ++ lib.optionals stdenv.isLinux [ acl attr e2fsprogs ]
  77     ++ lib.optional xarSupport libxml2;
  78
  79   # Without this, pkg-config-based dependencies are unhappy
  80   propagatedBuildInputs = lib.optionals stdenv.isLinux [ attr acl ];
  81
  82   configureFlags = lib.optional (!xarSupport) "--without-xml2";
  83
  84   preBuild = lib.optionalString stdenv.isCygwin ''
  85     echo "#include <windows.h>" >> config.h
  86   '';
  87
  88   # https://github.com/libarchive/libarchive/issues/1475
  89   doCheck = !stdenv.hostPlatform.isMusl;
  90
  91   preFixup = ''
  92     sed -i $lib/lib/libarchive.la \
  93       -e 's|-lcrypto|-L${lib.getLib openssl}/lib -lcrypto|' \
  94       -e 's|-llzo2|-L${lzo}/lib -llzo2|'
  95   '';
  96
  97   enableParallelBuilding = true;
  98
  99   meta = with lib; {
 100     homepage = "http://libarchive.org";
 101     description = "Multi-format archive and compression library";
 102     longDescription = ''
 103       The libarchive project develops a portable, efficient C library that can
 104       read and write streaming archives in a variety of formats. It also
 105       includes implementations of the common tar, cpio, and zcat command-line
 106       tools that use the libarchive library.
 107     '';
 108     changelog = "https://github.com/libarchive/libarchive/releases/tag/v${version}";
 109     license = licenses.bsd3;
 110     maintainers = with maintainers; [ jcumming AndersonTorres ];
 111     platforms = platforms.all;
 112   };
 113
 114   passthru.tests = {
 115     inherit cmake nix samba;
 116   };
 117 }