pkgs/development/libraries/libcanberra/default.nix

   1 { stdenv, lib, fetchurl, fetchpatch, pkg-config, libtool
   2 , gtk2-x11, gtk3-x11 , gtkSupport ? null
   3 , libpulseaudio, gst_all_1, libvorbis, libcap
   4 , Carbon, CoreServices, AppKit
   5 , withAlsa ? stdenv.isLinux, alsa-lib }:
   6
   7 stdenv.mkDerivation rec {
   8   pname = "libcanberra";
   9   version = "0.30";
  10
  11   src = fetchurl {
  12     url = "http://0pointer.de/lennart/projects/libcanberra/${pname}-${version}.tar.xz";
  13     sha256 = "0wps39h8rx2b00vyvkia5j40fkak3dpipp1kzilqla0cgvk73dn2";
  14   };
  15
  16   strictDeps = true;
  17   nativeBuildInputs = [ pkg-config ];
  18   buildInputs = [
  19     libpulseaudio libvorbis
  20     libtool # in buildInputs rather than nativeBuildInputs since libltdl is used (not libtool itself)
  21   ] ++ (with gst_all_1; [ gstreamer gst-plugins-base ])
  22     ++ lib.optional (gtkSupport == "gtk2") gtk2-x11
  23     ++ lib.optional (gtkSupport == "gtk3") gtk3-x11
  24     ++ lib.optionals stdenv.isDarwin [ Carbon CoreServices AppKit ]
  25     ++ lib.optional stdenv.isLinux libcap
  26     ++ lib.optional withAlsa alsa-lib;
  27
  28   configureFlags = [ "--disable-oss" ];
  29
  30   patches = [
  31     (fetchpatch {
  32       name = "0001-gtk-Don-t-assume-all-GdkDisplays-are-GdkX11Displays-.patch";
  33       url = "http://git.0pointer.net/libcanberra.git/patch/?id=c0620e432650e81062c1967cc669829dbd29b310";
  34       sha256 = "0rc7zwn39yxzxp37qh329g7375r5ywcqcaak8ryd0dgvg8m5hcx9";
  35     })
  36   ] ++ lib.optionals stdenv.isDarwin [
  37     (fetchpatch {
  38       url = "https://github.com/macports/macports-ports/raw/5a7965dfea7727d1ceedee46c7b0ccee9cb23468/audio/libcanberra/files/patch-configure.diff";
  39       sha256 = "sha256-pEJy1krciUEg5BFIS8FJ4BubjfS/nt9aqi6BLnS1+4M=";
  40       extraPrefix = "";
  41     })
  42     (fetchpatch {
  43       url = "https://github.com/macports/macports-ports/raw/5a7965dfea7727d1ceedee46c7b0ccee9cb23468/audio/libcanberra/files/dynamic_lookup-11.patch";
  44       sha256 = "sha256-nUjha2pKh5VZl0ZZzcr9NTo1TVuMqF4OcLiztxW+ofQ=";
  45       extraPrefix = "";
  46     })
  47   ];
  48
  49   postInstall = ''
  50     for f in $out/lib/*.la; do
  51       sed 's|-lltdl|-L${libtool.lib}/lib -lltdl|' -i $f
  52     done
  53   '';
  54
  55   passthru = lib.optionalAttrs (gtkSupport != null) {
  56     gtkModule = if gtkSupport == "gtk2" then "/lib/gtk-2.0" else "/lib/gtk-3.0/";
  57   };
  58
  59   meta = with lib; {
  60     description = "An implementation of the XDG Sound Theme and Name Specifications";
  61     longDescription = ''
  62       libcanberra is an implementation of the XDG Sound Theme and Name
  63       Specifications, for generating event sounds on free desktops
  64       such as GNOME.  It comes with several backends (ALSA,
  65       PulseAudio, OSS, GStreamer, null) and is designed to be
  66       portable.
  67     '';
  68     homepage = "http://0pointer.de/lennart/projects/libcanberra/";
  69     license = licenses.lgpl2Plus;
  70     maintainers = [ ];
  71     platforms = platforms.unix;
  72   };
  73 }