pkgs/development/libraries/libqalculate/default.nix

   1 { lib, stdenv, fetchFromGitHub
   2 , mpfr, gnuplot
   3 , readline
   4 , libxml2, curl
   5 , intltool, libiconv, icu, gettext
   6 , pkg-config, doxygen, autoreconfHook, buildPackages
   7 }:
   8
   9 stdenv.mkDerivation rec {
  10   pname = "libqalculate";
  11   version = "4.4.0";
  12
  13   src = fetchFromGitHub {
  14     owner = "qalculate";
  15     repo = "libqalculate";
  16     rev = "v${version}";
  17     sha256 = "sha256-/TgsGlO8RJ3L+2425odye365QqBzCHrr1Z4zUj+Ld8I=";
  18   };
  19
  20   outputs = [ "out" "dev" "doc" ];
  21
  22   nativeBuildInputs = [ intltool pkg-config autoreconfHook doxygen ];
  23   buildInputs = [ curl gettext libiconv readline ];
  24   depsBuildBuild = [ buildPackages.stdenv.cc ];
  25   propagatedBuildInputs = [ libxml2 mpfr icu ];
  26   enableParallelBuilding = true;
  27
  28   preConfigure = ''
  29     intltoolize -f
  30   '';
  31
  32   patchPhase = ''
  33     substituteInPlace libqalculate/Calculator-plot.cc \
  34       --replace 'commandline = "gnuplot"' 'commandline = "${gnuplot}/bin/gnuplot"' \
  35       --replace '"gnuplot - ' '"${gnuplot}/bin/gnuplot - '
  36   '' + lib.optionalString stdenv.cc.isClang ''
  37     substituteInPlace src/qalc.cc \
  38       --replace 'printf(_("aborted"))' 'printf("%s", _("aborted"))'
  39   '';
  40
  41   preBuild = ''
  42     pushd docs/reference
  43     doxygen Doxyfile
  44     popd
  45   '';
  46
  47   meta = with lib; {
  48     description = "An advanced calculator library";
  49     homepage = "http://qalculate.github.io";
  50     license = licenses.gpl2Plus;
  51     maintainers = with maintainers; [ gebner doronbehar alyaeanyx ];
  52     mainProgram = "qalc";
  53     platforms = platforms.all;
  54   };
  55 }