pkgs/development/libraries/matrix-sdk-crypto-nodejs/default.nix

   1 { lib, stdenv, fetchFromGitHub, rustPlatform, napi-rs-cli, nodejs, libiconv }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "matrix-sdk-crypto-nodejs";
   5   version = "0.1.0-beta.2";
   6
   7   src = fetchFromGitHub {
   8     owner = "matrix-org";
   9     repo = "matrix-rust-sdk";
  10     rev = "${pname}-v${version}";
  11     hash = "sha256-E++0tm/2d8/3zAXwovJ71uF2sxDORWyJNnA3e1Q3NLA=";
  12   };
  13
  14   patches = [
  15     # This is needed because two versions of indexed_db_futures are present (which will fail to vendor, see https://github.com/rust-lang/cargo/issues/10310).
  16     # (matrix-sdk-crypto-nodejs doesn't use this dependency, we only need to remove it to vendor the dependencies successfully.)
  17     ./remove-duplicate-dependency.patch
  18   ];
  19
  20   cargoDeps = rustPlatform.fetchCargoTarball {
  21     inherit src patches;
  22     name = "${pname}-${version}";
  23     hash = "sha256-G2Um7vHinOuOx9U2BH14LAx+s/0Sxtlc9Nz6nPJfmU8=";
  24   };
  25
  26   nativeBuildInputs = [
  27     rustPlatform.cargoSetupHook
  28     rustPlatform.rust.cargo
  29     rustPlatform.rust.rustc
  30     napi-rs-cli
  31     nodejs
  32   ];
  33
  34   buildInputs = lib.optionals stdenv.isDarwin [ libiconv ];
  35
  36   buildPhase = ''
  37     runHook preBuild
  38
  39     cd bindings/${pname}
  40     npm run release-build --offline
  41
  42     runHook postBuild
  43   '';
  44
  45   installPhase = ''
  46     runHook preInstall
  47
  48     local -r outPath="$out/lib/node_modules/@matrix-org/${pname}"
  49     mkdir -p "$outPath"
  50     cp package.json index.js index.d.ts matrix-sdk-crypto.*.node "$outPath"
  51
  52     runHook postInstall
  53   '';
  54
  55   meta = with lib; {
  56     description = "A no-network-IO implementation of a state machine that handles E2EE for Matrix clients";
  57     homepage = "https://github.com/matrix-org/matrix-rust-sdk/tree/${src.rev}/bindings/matrix-sdk-crypto-nodejs";
  58     license = licenses.asl20;
  59     maintainers = with maintainers; [ winter ];
  60     inherit (nodejs.meta) platforms;
  61   };
  62 }