pkgs/development/libraries/nss/generic.nix

   1 { version, hash }:
   2 { lib
   3 , stdenv
   4 , fetchurl
   5 , nspr
   6 , perl
   7 , zlib
   8 , sqlite
   9 , ninja
  10 , darwin
  11 , fixDarwinDylibNames
  12 , buildPackages
  13 , useP11kit ? true
  14 , p11-kit
  15 , # allow FIPS mode. Note that this makes the output non-reproducible.
  16   # https://developer.mozilla.org/en-US/docs/Mozilla/Projects/NSS/NSS_Tech_Notes/nss_tech_note6
  17   enableFIPS ? false
  18 , nixosTests
  19 }:
  20
  21 let
  22   underscoreVersion = lib.replaceStrings [ "." ] [ "_" ] version;
  23 in
  24 stdenv.mkDerivation rec {
  25   pname = "nss";
  26   inherit version;
  27
  28   src = fetchurl {
  29     url = "mirror://mozilla/security/nss/releases/NSS_${underscoreVersion}_RTM/src/${pname}-${version}.tar.gz";
  30     inherit hash;
  31   };
  32
  33   depsBuildBuild = [ buildPackages.stdenv.cc ];
  34
  35   nativeBuildInputs = [ perl ninja (buildPackages.python3.withPackages (ps: with ps; [ gyp ])) ]
  36     ++ lib.optionals stdenv.hostPlatform.isDarwin [ darwin.cctools fixDarwinDylibNames ];
  37
  38   buildInputs = [ zlib sqlite ];
  39
  40   propagatedBuildInputs = [ nspr ];
  41
  42   patches = [
  43     # Based on http://patch-tracker.debian.org/patch/series/dl/nss/2:3.15.4-1/85_security_load.patch
  44     (if (lib.versionOlder version "3.77") then
  45       ./85_security_load.patch
  46     else
  47       ./85_security_load_3.77+.patch
  48     )
  49     ./fix-cross-compilation.patch
  50   ];
  51
  52   patchFlags = [ "-p0" ];
  53
  54   postPatch = ''
  55     patchShebangs nss
  56
  57     for f in nss/coreconf/config.gypi nss/build.sh nss/coreconf/config.gypi; do
  58       substituteInPlace "$f" --replace "/usr/bin/env" "${buildPackages.coreutils}/bin/env"
  59     done
  60
  61     substituteInPlace nss/coreconf/config.gypi --replace "/usr/bin/grep" "${buildPackages.coreutils}/bin/env grep"
  62   '' + lib.optionalString stdenv.hostPlatform.isDarwin ''
  63     substituteInPlace nss/coreconf/Darwin.mk --replace '@executable_path/$(notdir $@)' "$out/lib/\$(notdir \$@)"
  64     substituteInPlace nss/coreconf/config.gypi --replace "'DYLIB_INSTALL_NAME_BASE': '@executable_path'" "'DYLIB_INSTALL_NAME_BASE': '$out/lib'"
  65   '';
  66
  67   outputs = [ "out" "dev" "tools" ];
  68
  69   preConfigure = "cd nss";
  70
  71   buildPhase =
  72     let
  73       getArch = platform:
  74         if platform.isx86_64 then "x64"
  75         else if platform.isx86_32 then "ia32"
  76         else if platform.isAarch32 then "arm"
  77         else if platform.isAarch64 then "arm64"
  78         else if platform.isPower && platform.is64bit then
  79           (
  80             if platform.isLittleEndian then "ppc64le" else "ppc64"
  81           )
  82         else platform.parsed.cpu.name;
  83       # yes, this is correct. nixpkgs uses "host" for the platform the binary will run on whereas nss uses "host" for the platform that the build is running on
  84       target = getArch stdenv.hostPlatform;
  85       host = getArch stdenv.buildPlatform;
  86     in
  87     ''
  88       runHook preBuild
  89
  90       sed -i 's|nss_dist_dir="$dist_dir"|nss_dist_dir="'$out'"|;s|nss_dist_obj_dir="$obj_dir"|nss_dist_obj_dir="'$out'"|' build.sh
  91       ./build.sh -v --opt \
  92         --with-nspr=${nspr.dev}/include:${nspr.out}/lib \
  93         --system-sqlite \
  94         --enable-legacy-db \
  95         --target ${target} \
  96         -Dhost_arch=${host} \
  97         -Duse_system_zlib=1 \
  98         --enable-libpkix \
  99         ${lib.optionalString enableFIPS "--enable-fips"} \
 100         ${lib.optionalString stdenv.isDarwin "--clang"} \
 101         ${lib.optionalString (stdenv.hostPlatform != stdenv.buildPlatform) "--disable-tests"}
 102
 103       runHook postBuild
 104     '';
 105
 106   NIX_CFLAGS_COMPILE = "-Wno-error -DNIX_NSS_LIBDIR=\"${placeholder "out"}/lib/\" " + lib.optionalString stdenv.hostPlatform.is64bit "-DNSS_USE_64=1";
 107
 108   installPhase = ''
 109     runHook preInstall
 110
 111     rm -rf $out/private
 112     find $out -name "*.TOC" -delete
 113     mv $out/public $out/include
 114
 115     ln -s lib $out/lib64
 116
 117     # Upstream issue: https://bugzilla.mozilla.org/show_bug.cgi?id=530672
 118     # https://gitweb.gentoo.org/repo/gentoo.git/plain/dev-libs/nss/files/nss-3.32-gentoo-fixups.patch?id=af1acce6c6d2c3adb17689261dfe2c2b6771ab8a
 119     NSS_MAJOR_VERSION=`grep "NSS_VMAJOR" lib/nss/nss.h | awk '{print $3}'`
 120     NSS_MINOR_VERSION=`grep "NSS_VMINOR" lib/nss/nss.h | awk '{print $3}'`
 121     NSS_PATCH_VERSION=`grep "NSS_VPATCH" lib/nss/nss.h | awk '{print $3}'`
 122     PREFIX="$out"
 123
 124     mkdir -p $out/lib/pkgconfig
 125     sed -e "s,%prefix%,$PREFIX," \
 126         -e "s,%exec_prefix%,$PREFIX," \
 127         -e "s,%libdir%,$PREFIX/lib64," \
 128         -e "s,%includedir%,$dev/include/nss," \
 129         -e "s,%NSS_VERSION%,$NSS_MAJOR_VERSION.$NSS_MINOR_VERSION.$NSS_PATCH_VERSION,g" \
 130         -e "s,%NSPR_VERSION%,4.16,g" \
 131         pkg/pkg-config/nss.pc.in > $out/lib/pkgconfig/nss.pc
 132     chmod 0644 $out/lib/pkgconfig/nss.pc
 133
 134     sed -e "s,@prefix@,$PREFIX," \
 135         -e "s,@MOD_MAJOR_VERSION@,$NSS_MAJOR_VERSION," \
 136         -e "s,@MOD_MINOR_VERSION@,$NSS_MINOR_VERSION," \
 137         -e "s,@MOD_PATCH_VERSION@,$NSS_PATCH_VERSION," \
 138         pkg/pkg-config/nss-config.in > $out/bin/nss-config
 139     chmod 0755 $out/bin/nss-config
 140   '';
 141
 142   postInstall = lib.optionalString useP11kit ''
 143     # Replace built-in trust with p11-kit connection
 144     ln -sf ${p11-kit}/lib/pkcs11/p11-kit-trust.so $out/lib/libnssckbi.so
 145   '';
 146
 147   postFixup =
 148     let
 149       isCross = stdenv.hostPlatform != stdenv.buildPlatform;
 150       nss = if isCross then buildPackages.nss.tools else "$out";
 151     in
 152     (lib.optionalString enableFIPS (''
 153       for libname in freebl3 nssdbm3 softokn3
 154       do libfile="$out/lib/lib$libname${stdenv.hostPlatform.extensions.sharedLibrary}"'' +
 155     (if stdenv.isDarwin
 156     then ''
 157       DYLD_LIBRARY_PATH=$out/lib:${nspr.out}/lib \
 158     '' else ''
 159       LD_LIBRARY_PATH=$out/lib:${nspr.out}/lib \
 160     '') + ''
 161           ${nss}/bin/shlibsign -v -i "$libfile"
 162       done
 163     '')) +
 164     ''
 165       moveToOutput bin "$tools"
 166       moveToOutput bin/nss-config "$dev"
 167       moveToOutput lib/libcrmf.a "$dev" # needed by firefox, for example
 168       rm -f "$out"/lib/*.a
 169
 170       runHook postInstall
 171     '';
 172
 173   passthru.updateScript = ./update.sh;
 174
 175   passthru.tests = lib.optionalAttrs (lib.versionOlder version "3.69") {
 176     inherit (nixosTests) firefox-esr-91;
 177   } // lib.optionalAttrs (lib.versionAtLeast version "3.69") {
 178     inherit (nixosTests) firefox firefox-esr-102;
 179   };
 180
 181   meta = with lib; {
 182     homepage = "https://developer.mozilla.org/en-US/docs/Mozilla/Projects/NSS";
 183     description = "A set of libraries for development of security-enabled client and server applications";
 184     changelog = "https://github.com/nss-dev/nss/blob/master/doc/rst/releases/nss_${underscoreVersion}.rst";
 185     maintainers = with maintainers; [ hexa ajs124 ];
 186     license = licenses.mpl20;
 187     platforms = platforms.all;
 188   };
 189 }