pkgs/development/libraries/polkit/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitLab
   4 , pkg-config
   5 , glib
   6 , expat
   7 , pam
   8 , meson
   9 , mesonEmulatorHook
  10 , ninja
  11 , perl
  12 , rsync
  13 , python3
  14 , fetchpatch
  15 , gettext
  16 , duktape
  17 , gobject-introspection
  18 , libxslt
  19 , docbook-xsl-nons
  20 , dbus
  21 , docbook_xml_dtd_412
  22 , gtk-doc
  23 , coreutils
  24 , useSystemd ? stdenv.isLinux
  25 , systemdMinimal
  26 , elogind
  27 # A few tests currently fail on musl (polkitunixusertest, polkitunixgrouptest, polkitidentitytest segfault).
  28 # Not yet investigated; it may be due to the "Make netgroup support optional"
  29 # patch not updating the tests correctly yet, or doing something wrong,
  30 # or being unrelated to that.
  31 , doCheck ? (stdenv.isLinux && !stdenv.hostPlatform.isMusl)
  32 }:
  33
  34 let
  35   system = "/run/current-system/sw";
  36   setuid = "/run/wrappers/bin";
  37 in
  38 stdenv.mkDerivation rec {
  39   pname = "polkit";
  40   version = "121";
  41
  42   outputs = [ "bin" "dev" "out" ]; # small man pages in $bin
  43
  44   # Tarballs do not contain subprojects.
  45   src = fetchFromGitLab {
  46     domain = "gitlab.freedesktop.org";
  47     owner = "polkit";
  48     repo = "polkit";
  49     rev = version;
  50     sha256 = "Lj7KSGILc6CBsNqPO0G0PNt6ClikbRG45E8FZbb46yY=";
  51   };
  52
  53   patches = [
  54     # Allow changing base for paths in pkg-config file as before.
  55     # https://gitlab.freedesktop.org/polkit/polkit/-/merge_requests/100
  56     (fetchpatch {
  57       url = "https://gitlab.freedesktop.org/polkit/polkit/-/commit/7ba07551dfcd4ef9a87b8f0d9eb8b91fabcb41b3.patch";
  58       sha256 = "ebbLILncq1hAZTBMsLm+vDGw6j0iQ0crGyhzyLZQgKA=";
  59     })
  60     # Make netgroup support optional (musl does not have it)
  61     # Upstream MR: https://gitlab.freedesktop.org/polkit/polkit/merge_requests/10
  62     # NOTE: Remove after the next release
  63     (fetchpatch {
  64       name = "make-innetgr-optional.patch";
  65       url = "https://gitlab.freedesktop.org/polkit/polkit/-/commit/b57deee8178190a7ecc75290fa13cf7daabc2c66.patch";
  66       sha256 = "8te6gatT9Fp+fIT05fQBym5mEwHeHfaUNUNEMfSbtLc=";
  67     })
  68   ];
  69
  70   depsBuildBuild = [
  71     pkg-config
  72   ];
  73
  74   nativeBuildInputs = [
  75     glib
  76     gtk-doc
  77     pkg-config
  78     gettext
  79     meson
  80     ninja
  81     perl
  82     rsync
  83     gobject-introspection
  84     (python3.pythonForBuild.withPackages (pp: with pp; [
  85       dbus-python
  86       (python-dbusmock.overridePythonAttrs (attrs: {
  87         # Avoid dependency cycle.
  88         doCheck = false;
  89       }))
  90     ]))
  91
  92     # man pages
  93     libxslt
  94     docbook-xsl-nons
  95     docbook_xml_dtd_412
  96   ] ++ lib.optionals (!stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
  97     mesonEmulatorHook
  98   ];
  99
 100   buildInputs = [
 101     gobject-introspection
 102     expat
 103     pam
 104     dbus
 105     duktape
 106   ] ++ lib.optionals stdenv.isLinux [
 107     # On Linux, fall back to elogind when systemd support is off.
 108     (if useSystemd then systemdMinimal else elogind)
 109   ];
 110
 111   propagatedBuildInputs = [
 112     glib # in .pc Requires
 113   ];
 114
 115   checkInputs = [
 116     dbus
 117   ];
 118
 119   mesonFlags = [
 120     "--datadir=${system}/share"
 121     "--sysconfdir=/etc"
 122     "-Dsystemdsystemunitdir=${placeholder "out"}/etc/systemd/system"
 123     "-Dpolkitd_user=polkituser" #TODO? <nixos> config.ids.uids.polkituser
 124     "-Dos_type=redhat" # only affects PAM includes
 125     "-Dtests=${lib.boolToString doCheck}"
 126     "-Dman=true"
 127   ] ++ lib.optionals stdenv.isLinux [
 128     "-Dsession_tracking=${if useSystemd then "libsystemd-login" else "libelogind"}"
 129   ];
 130
 131   # HACK: We want to install policy files files to $out/share but polkit
 132   # should read them from /run/current-system/sw/share on a NixOS system.
 133   # Similarly for config files in /etc.
 134   # With autotools, it was possible to override Make variables
 135   # at install time but Meson does not support this
 136   # so we need to convince it to install all files to a temporary
 137   # location using DESTDIR and then move it to proper one in postInstall.
 138   DESTDIR = "${placeholder "out"}/dest";
 139
 140   inherit doCheck;
 141
 142   postPatch = ''
 143     patchShebangs test/polkitbackend/polkitbackendjsauthoritytest-wrapper.py
 144
 145     # ‘libpolkit-agent-1.so’ should call the setuid wrapper on
 146     # NixOS.  Hard-coding the path is kinda ugly.  Maybe we can just
 147     # call through $PATH, but that might have security implications.
 148     substituteInPlace src/polkitagent/polkitagentsession.c \
 149       --replace   'PACKAGE_PREFIX "/lib/polkit-1/'   '"${setuid}/'
 150     substituteInPlace test/data/etc/polkit-1/rules.d/10-testing.rules \
 151       --replace   /bin/true ${coreutils}/bin/true \
 152       --replace   /bin/false ${coreutils}/bin/false
 153   '';
 154
 155   postConfigure = lib.optionalString (!stdenv.hostPlatform.isMusl) ''
 156     # Unpacked by meson
 157     chmod +x subprojects/mocklibc-1.0/bin/mocklibc
 158     patchShebangs subprojects/mocklibc-1.0/bin/mocklibc
 159   '';
 160
 161   checkPhase = ''
 162     runHook preCheck
 163
 164     # tests need access to the system bus
 165     dbus-run-session --config-file=${./system_bus.conf} -- sh -c 'DBUS_SYSTEM_BUS_ADDRESS=$DBUS_SESSION_BUS_ADDRESS meson test --print-errorlogs'
 166
 167     runHook postCheck
 168   '';
 169
 170   postInstall = ''
 171     # Move stuff from DESTDIR to proper location.
 172     # We use rsync to merge the directories.
 173     rsync --archive "${DESTDIR}/etc" "$out"
 174     rm --recursive "${DESTDIR}/etc"
 175     rsync --archive "${DESTDIR}${system}"/* "$out"
 176     rm --recursive "${DESTDIR}${system}"/*
 177     rmdir --parents --ignore-fail-on-non-empty "${DESTDIR}${system}"
 178     for o in $outputs; do
 179         rsync --archive "${DESTDIR}/''${!o}" "$(dirname "''${!o}")"
 180         rm --recursive "${DESTDIR}/''${!o}"
 181     done
 182     # Ensure the DESTDIR is removed.
 183     destdirContainer="$(dirname "${DESTDIR}")"
 184     pushd "$destdirContainer"; rmdir --parents "''${DESTDIR##$destdirContainer/}${builtins.storeDir}"; popd
 185   '';
 186
 187   meta = with lib; {
 188     homepage = "http://www.freedesktop.org/wiki/Software/polkit";
 189     description = "A toolkit for defining and handling the policy that allows unprivileged processes to speak to privileged processes";
 190     license = licenses.lgpl2Plus;
 191     platforms = platforms.linux;
 192     maintainers = teams.freedesktop.members ++ (with maintainers; [ ]);
 193   };
 194 }