pkgs/development/libraries/qscintilla/default.nix

   1 { stdenv
   2 , lib
   3 , fetchurl
   4 , unzip
   5 , qtbase
   6 , qtmacextras
   7 , qmake
   8 , fixDarwinDylibNames
   9 }:
  10
  11 stdenv.mkDerivation rec {
  12   pname = "qscintilla-qt5";
  13   version = "2.13.2";
  14
  15   src = fetchurl {
  16     url = "https://www.riverbankcomputing.com/static/Downloads/QScintilla/${version}/QScintilla_src-${version}.tar.gz";
  17     sha256 = "sha256-tsfl8ntR0l8J/mz4Sumn8Idq8NZdjMtVEQnm57JYhfQ=";
  18   };
  19
  20   sourceRoot = "QScintilla_src-${version}/src";
  21
  22   buildInputs = [ qtbase ];
  23
  24   propagatedBuildInputs = lib.optionals stdenv.isDarwin [ qtmacextras ];
  25
  26   nativeBuildInputs = [ unzip qmake ]
  27     ++ lib.optionals stdenv.isDarwin [ fixDarwinDylibNames ];
  28
  29   # Make sure that libqscintilla2.so is available in $out/lib since it is expected
  30   # by some packages such as sqlitebrowser
  31   postFixup = ''
  32     ln -s $out/lib/libqscintilla2_qt5.so $out/lib/libqscintilla2.so
  33   '';
  34
  35   dontWrapQtApps = true;
  36
  37   preConfigure = ''
  38     substituteInPlace qscintilla.pro \
  39       --replace '$$[QT_INSTALL_LIBS]'         $out/lib \
  40       --replace '$$[QT_INSTALL_HEADERS]'      $out/include \
  41       --replace '$$[QT_INSTALL_TRANSLATIONS]' $out/translations \
  42       --replace '$$[QT_HOST_DATA]/mkspecs'    $out/mkspecs \
  43       --replace '$$[QT_INSTALL_DATA]'         $out/share
  44   '';
  45
  46   meta = with lib; {
  47     description = "A Qt port of the Scintilla text editing library";
  48     longDescription = ''
  49       QScintilla is a port to Qt of Neil Hodgson's Scintilla C++ editor
  50       control.
  51
  52       As well as features found in standard text editing components,
  53       QScintilla includes features especially useful when editing and
  54       debugging source code. These include support for syntax styling,
  55       error indicators, code completion and call tips. The selection
  56       margin can contain markers like those used in debuggers to
  57       indicate breakpoints and the current line. Styling choices are
  58       more open than with many editors, allowing the use of
  59       proportional fonts, bold and italics, multiple foreground and
  60       background colours and multiple fonts.
  61     '';
  62     homepage = "https://www.riverbankcomputing.com/software/qscintilla/intro";
  63     license = with licenses; [ gpl3 ]; # and commercial
  64     maintainers = with maintainers; [ peterhoeg ];
  65     platforms = platforms.unix;
  66   };
  67 }