pkgs/development/libraries/qt-6/qtModule.nix

   1 { stdenv, lib, perl, cmake, ninja, writeText }:
   2
   3 { self, srcs, patches ? [ ] }:
   4
   5 args:
   6
   7 let
   8   inherit (args) pname;
   9   version = args.version or srcs.${pname}.version;
  10   src = args.src or srcs.${pname}.src;
  11 in
  12 stdenv.mkDerivation (args // {
  13   inherit pname version src;
  14   patches = args.patches or patches.${pname} or [ ];
  15
  16   buildInputs = args.buildInputs or [ ];
  17   nativeBuildInputs = (args.nativeBuildInputs or [ ]) ++ [
  18     perl
  19     cmake
  20     ninja
  21     self.qmake
  22   ];
  23   propagatedBuildInputs = args.qtInputs ++ (args.propagatedBuildInputs or [ ]);
  24
  25   preHook = ''
  26     . ${./hooks/move-qt-dev-tools.sh}
  27     . ${./hooks/fix-qt-builtin-paths.sh}
  28   '';
  29
  30   outputs = args.outputs or [ "out" "dev" ];
  31
  32   dontWrapQtApps = args.dontWrapQtApps or true;
  33   postInstall = ''
  34     if [ ! -z "$dev" ]; then
  35       mkdir "$dev"
  36       for dir in bin libexec mkspecs
  37       do
  38         moveToOutput "$dir" "$dev"
  39       done
  40     fi
  41     fixQtBuiltinPaths $out/lib "*.pr?"
  42     ${args.postInstall or ""}
  43   '';
  44
  45   preConfigure = args.preConfigure or "" + ''
  46     fixQtBuiltinPaths . '*.pr?'
  47   '' + lib.optionalString (builtins.compareVersions "5.15.0" version <= 0)
  48     # Note: We use ${version%%-*} to remove any tag from the end of the version
  49     # string. Version tags are added by Nixpkgs maintainers and not reflected in
  50     # the source version.
  51     ''
  52       if [[ -z "$dontCheckQtModuleVersion" ]] \
  53           && grep -q '^MODULE_VERSION' .qmake.conf 2>/dev/null \
  54           && ! grep -q -F "''${version%%-*}" .qmake.conf 2>/dev/null
  55       then
  56         echo >&2 "error: could not find version ''${version%%-*} in .qmake.conf"
  57         echo >&2 "hint: check .qmake.conf and update the package version in Nixpkgs"
  58         exit 1
  59       fi
  60
  61       if [[ -z "$dontSyncQt" && -f sync.profile ]]; then
  62         # FIXME: this probably breaks crosscompiling as it's not from nativeBuildInputs
  63         # I don't know how to get /libexec from nativeBuildInputs to work, it's not under /bin
  64         ${self.qtbase.dev.nativeDrv or self.qtbase.dev}/libexec/syncqt.pl -version "''${version%%-*}"
  65       fi
  66     '';
  67
  68   postFixup = ''
  69     if [ -d "''${!outputDev}/lib/pkgconfig" ]; then
  70       find "''${!outputDev}/lib/pkgconfig" -name '*.pc' | while read pc; do
  71         sed -i "$pc" \
  72           -e "/^prefix=/ c prefix=''${!outputLib}" \
  73           -e "/^exec_prefix=/ c exec_prefix=''${!outputBin}" \
  74           -e "/^includedir=/ c includedir=''${!outputDev}/include"
  75       done
  76     fi
  77
  78     moveQtDevTools
  79   '' + args.postFixup or "";
  80
  81   meta = with lib; {
  82     homepage = "https://www.qt.io/";
  83     description = "A cross-platform application framework for C++";
  84     license = with licenses; [ fdl13Plus gpl2Plus lgpl21Plus lgpl3Plus ];
  85     maintainers = with maintainers; [ milahu nickcao ];
  86     platforms = platforms.linux;
  87   } // (args.meta or { });
  88 })