pkgs/development/tools/pipenv/default.nix

   1 { lib
   2 , stdenv
   3 , python3
   4 , installShellFiles
   5 }:
   6
   7 with python3.pkgs;
   8
   9 let
  10
  11   runtimeDeps = ps: with ps; [
  12     certifi
  13     setuptools
  14     pip
  15     virtualenv
  16     virtualenv-clone
  17   ]
  18   ++ lib.optionals stdenv.hostPlatform.isAndroid [
  19     pyjnius
  20   ];
  21
  22   pythonEnv = python3.withPackages runtimeDeps;
  23
  24 in buildPythonApplication rec {
  25   pname = "pipenv";
  26   version = "2022.10.25";
  27
  28   src = fetchPypi {
  29     inherit pname version;
  30     sha256 = "sha256-PjnI1aK8qrMkVSoYV2EFwqNeAguzEf9T106stYuFGFM=";
  31   };
  32
  33   LC_ALL = "en_US.UTF-8";
  34
  35   nativeBuildInputs = [ installShellFiles ];
  36
  37   postPatch = ''
  38     # pipenv invokes python in a subprocess to create a virtualenv
  39     # and to call setup.py.
  40     # It would use sys.executable, which in our case points to a python that
  41     # does not have the required dependencies.
  42     substituteInPlace pipenv/core.py \
  43       --replace "sys.executable" "'${pythonEnv.interpreter}'"
  44   '';
  45
  46   propagatedBuildInputs = runtimeDeps python3.pkgs;
  47
  48   postInstall = ''
  49     installShellCompletion --cmd pipenv \
  50       --bash <(_PIPENV_COMPLETE=bash_source $out/bin/pipenv) \
  51       --zsh <(_PIPENV_COMPLETE=zsh_source $out/bin/pipenv) \
  52       --fish <(_PIPENV_COMPLETE=fish_source $out/bin/pipenv)
  53   '';
  54
  55   doCheck = true;
  56   checkPhase = ''
  57     export HOME=$(mktemp -d)
  58     cp -r --no-preserve=mode ${wheel.src} $HOME/wheel-src
  59     $out/bin/pipenv install $HOME/wheel-src
  60   '';
  61
  62   meta = with lib; {
  63     description = "Python Development Workflow for Humans";
  64     license = licenses.mit;
  65     platforms = platforms.all;
  66     maintainers = with maintainers; [ berdario ];
  67   };
  68 }