pkgs/development/tools/scalafmt/default.nix

   1 { lib, stdenv, jre, coursier, makeWrapper, setJavaClassPath }:
   2
   3 let
   4   baseName = "scalafmt";
   5   version = "3.5.2";
   6   deps = stdenv.mkDerivation {
   7     name = "${baseName}-deps-${version}";
   8     buildCommand = ''
   9       export COURSIER_CACHE=$(pwd)
  10       ${coursier}/bin/cs fetch org.scalameta:scalafmt-cli_2.13:${version} > deps
  11       mkdir -p $out/share/java
  12       cp $(< deps) $out/share/java/
  13     '';
  14     outputHashMode = "recursive";
  15     outputHash     = "sha256-1QP5a0QjYUDU3JzrIX2rM/DclRfU/ACSXVLd6C7uFCo=";
  16   };
  17 in
  18 stdenv.mkDerivation {
  19   pname = baseName;
  20   inherit version;
  21
  22   nativeBuildInputs = [ makeWrapper setJavaClassPath ];
  23   buildInputs = [ deps ];
  24
  25   dontUnpack = true;
  26
  27   installPhase = ''
  28     runHook preInstall
  29
  30     makeWrapper ${jre}/bin/java $out/bin/${baseName} \
  31       --add-flags "-cp $CLASSPATH org.scalafmt.cli.Cli"
  32
  33     runHook postInstall
  34   '';
  35
  36   installCheckPhase = ''
  37     $out/bin/${baseName} --version | grep -q "${version}"
  38   '';
  39
  40   meta = with lib; {
  41     description = "Opinionated code formatter for Scala";
  42     homepage = "http://scalameta.org/scalafmt";
  43     license = licenses.asl20;
  44     maintainers = [ maintainers.markus1189 ];
  45   };
  46 }