pkgs/games/ferium/default.nix

   1 { lib, stdenv, fetchFromGitHub, rustPlatform, Security, installShellFiles }:
   2
   3 rustPlatform.buildRustPackage rec {
   4   pname = "ferium";
   5   version = "4.2.0";
   6
   7   src = fetchFromGitHub {
   8     owner = "gorilla-devs";
   9     repo = pname;
  10     rev = "v${version}";
  11     sha256 = "sha256-pJis4Lab/qRc5taeTxSoJOvNrhsWhGJrPILvkmB8k2A=";
  12   };
  13
  14   buildInputs = lib.optionals stdenv.isDarwin [ Security ];
  15
  16   cargoSha256 = "sha256-J1BY0gSkUQRFZJ/UlikvQqrLvCjHlf2jxbg6BIoZZUE=";
  17
  18   # Disable the GUI file picker so that GTK/XDG dependencies aren't used
  19   buildNoDefaultFeatures = true;
  20
  21   # Requires an internet connection
  22   doCheck = false;
  23
  24   nativeBuildInputs = [ installShellFiles ];
  25
  26   postInstall = ''
  27     for shell in bash fish zsh; do
  28       $out/bin/ferium complete $shell > ferium.$shell
  29       installShellCompletion ferium.$shell
  30     done
  31   '';
  32
  33   meta = with lib; {
  34     description = "Fast and multi-source CLI program for managing Minecraft mods and modpacks from Modrinth, CurseForge, and GitHub Releases";
  35     homepage = "https://github.com/gorilla-devs/ferium";
  36     license = licenses.mpl20;
  37     maintainers = with maintainers; [ leo60228 imsofi ];
  38   };
  39 }