pkgs/games/gcs/default.nix

   1 { lib, stdenv, fetchFromGitHub, runCommand
   2 , jdk8, ant
   3 , jre8, makeWrapper
   4 }:
   5
   6 let
   7   gcs = fetchFromGitHub {
   8     owner = "richardwilkes";
   9     repo = "gcs";
  10     rev = "gcs-4.8.0";
  11     sha256 = "0k8am8vfwls5s2z4zj1p1aqy8gapn5vbr9zy66s5g048ch8ah1hm";
  12   };
  13   appleStubs = fetchFromGitHub {
  14     owner = "richardwilkes";
  15     repo = "apple_stubs";
  16     rev = "gcs-4.3.0";
  17     sha256 = "0m1qw30b19s04hj7nch1mbvv5s698g5dr1d1r7r07ykvk1yh7zsa";
  18   };
  19   toolkit = fetchFromGitHub {
  20     owner = "richardwilkes";
  21     repo = "toolkit";
  22     rev = "gcs-4.8.0";
  23     sha256 = "1ciwwh0wxk3pzsj6rbggsbg3l2f741qy7yx1ca4v7vflsma84f1n";
  24   };
  25   library = fetchFromGitHub {
  26     owner = "richardwilkes";
  27     repo = "gcs_library";
  28     rev = "gcs-4.8.0";
  29     sha256 = "085jpp9mpv5kw00zds9sywmfq31mrlbrgahnwcjkx0z9i22amz4g";
  30   };
  31 in stdenv.mkDerivation rec {
  32   pname = "gcs";
  33   version = "4.8.0";
  34
  35   src = runCommand "${pname}-${version}-src" { preferLocalBuild = true; } ''
  36     mkdir -p $out
  37     cd $out
  38
  39     cp -r ${gcs} gcs
  40     cp -r ${appleStubs} apple_stubs
  41     cp -r ${toolkit} toolkit
  42     cp -r ${library} gcs_library
  43   '';
  44
  45   nativeBuildInputs = [ makeWrapper ];
  46   buildInputs = [ jdk8 jre8 ant ];
  47   buildPhase = ''
  48     cd apple_stubs
  49     ant
  50
  51     cd ../toolkit
  52     ant
  53
  54     cd ../gcs
  55     ant
  56
  57     cd ..
  58   '';
  59
  60   installPhase = ''
  61     mkdir -p $out/bin $out/share/java
  62
  63     find gcs/libraries toolkit/libraries apple_stubs/ \( -name '*.jar' -and -not -name '*-src.jar' \) -exec cp '{}' $out/share/java ';'
  64
  65     makeWrapper ${jre8}/bin/java $out/bin/gcs \
  66       --set GCS_LIBRARY ${library} \
  67       --add-flags "-cp $out/share/java/gcs-${version}.jar com.trollworks.gcs.app.GCS"
  68   '';
  69
  70   meta = with lib; {
  71     description = "A stand-alone, interactive, character sheet editor for the GURPS 4th Edition roleplaying game system";
  72     homepage = "https://gurpscharactersheet.com/";
  73     sourceProvenance = with sourceTypes; [
  74       fromSource
  75       binaryBytecode  # source bundles dependencies as jars
  76     ];
  77     license = licenses.mpl20;
  78     platforms = platforms.all;
  79     maintainers = with maintainers; [];
  80   };
  81 }